部分镜片的组成

Question

我试图找出最简洁的方法来修改嵌套在Maybe类型(或其他类型的建模偏好)内的值.

以下是示例设置:

{-# LANGUAGE TemplateHaskell #-}

import Control.Lens

data Outer = Outer { _inner :: Maybe Inner }
  deriving (Show)

data Inner = Inner { _foo :: Int }
  deriving (Show)

makeLenses ''Outer
makeLenses ''Inner

通过以下方式以一种混乱的方式执行此操作非常容易lens:

wibble :: Outer -> Maybe Outer
wibble o = do i <- view inner o
              let i' = over foo succ i
              return $ set inner (Just i') o

为了说明为什么这是令人讨厌的,这是我想要写的:

wibble' :: Outer -> Maybe Outer
wibble' = overish inner.foo succ

overish = ???

查找字段失败应该只是使整个操作失败,而不是让我在可能发生的每个点上明确地检查失败.

有什么建议？我已经尝试了导航各种lens模块,但似乎没有任何东西适合该法案.

Answer 1

您可以使用over (inner.traverse.foo)写入嵌套字段.这不会以您想要的方式报告失败,因为它成功映射了所有0个目标.

traverse(来自Data.Traversable,再出口Control.Lens)这里给你一个Traversal走过的地方Maybe.

您可以从中读取(^?)以查看镜头的目标是否存在.

我们可以通过使用现有的镜头组合器分别进行读写来解决这个问题,但我们可以直接构建这样的组合器:

import Data.Monoid (Any(..))
import Control.Monad (guard)

overish :: LensLike ((,) Any) s t a b -> (a -> b) -> s -> Maybe t
overish l f s = case l (\a -> (Any True, f a)) s of
  (Any r, t) -> t <$ guard r

你也可以写这个l %%~ \a -> (Any True, f a).

您可以Traversal通过使用轻松检查是否没有目标nullOf,但这需要两次传递和更高级别的类型:

overish :: Traversal s t a b -> (a -> b) -> s -> Maybe t
overish l f s = over l f s <$ guard (not (nullOf l s))

这实际上只是检查是否存在目标,然后在有目标的情况下将setter应用于它.

然后你可以使用

overish (inner.traverse.foo) succ