如何在AWK中添加花在任务上的小时和分钟？

Question

时间跟踪工具打卡生成一个时间日志,其中包含"yyyymmddThhmmss"中的任务和时间戳:

task    started         ended
---------------------------------------
task1   20121107T114348 20121107T120921
task2   20121107T121349 20121107T121430
task2   20121107T121658 20121107T124255
task1   20121107T140935 20121107T144153
task2   20121107T163449 20121107T180431

我如何计算正则表达式中指定的每个任务所花费的总小时数和分钟数？例如,为了增加在包含的任务上花费的时间my-regex,awk或者gawk命令将是这样的:

awk '/my-regex/ { summing-of-corresponding-timestamps }' logfile.log

这是我之前的问题的补充- 我意识到我需要一个更"强大",基于正则表达式的解决方案.但我不是编码员,所以在AWK中总结分钟和小时让我感到非常困惑.谢谢你的帮助!

Answer 1

尝试使用GNU awk,我没有检查数学:

$ cat tst.awk
NR<3{ next }
{
   start = mktime(gensub(/(....)(..)(..).(..)(..)(..)/,"\\1 \\2 \\3 \\4 \\5 \\6","",$2))
   end   = mktime(gensub(/(....)(..)(..).(..)(..)(..)/,"\\1 \\2 \\3 \\4 \\5 \\6","",$3))
   dur[$1] += end - start
}
END {
   for (task in dur)
      print task, dur[task]
}
$
$ gawk -f tst.awk file
task1 3471
task2 6980

几秒钟内的输​​出,按摩以适应......

编辑:获得满足某些RE的所有任务的总持续时间将是:

NR<3{ next }
$1 ~ re {
   start = mktime(gensub(/(....)(..)(..).(..)(..)(..)/,"\\1 \\2 \\3 \\4 \\5 \\6","",$2))
   end   = mktime(gensub(/(....)(..)(..).(..)(..)(..)/,"\\1 \\2 \\3 \\4 \\5 \\6","",$3))
   dur += end - start
}
END {
   print dur
}

$ gawk -v re='<specify your RE>' -f tst.awk file

史蒂夫的编辑:

这个答案几乎就在那里.我在上面/下面的评论中做了一些小改动.您可以根据需要更改正则表达式,例如:

awk '/task/ { a = "(....)(..)(..).(..)(..)(..)"; b = "\\1 \\2 \\3 \\4 \\5 \\6"; t += mktime(gensub(a, b, "", $NF)) - mktime(gensub(a, b, "", $(NF-1))) } END { print t }' file

结果:

10451