如何重载父类中引入的虚函数？

Question

我有一个父类,有一个重要的抽象过程,我在许多子类中重载,如下所示的示例代码:

TCParent = Class
private
public
 procedure SaveConfig; virtual; abstract;

end;

TCChild = Class(TCParent)
private
public
 procedure SaveConfig; override;
end;

现在,我需要(重载)此过程与另一个接受参数的SaveConfig过程,但我不想在父类中进行大的更改,这可能需要我去所有其他子类中进行更改.

有没有一种方法可以在这个特定的子类中重载SaveConfig而不对父类和从它继承的其他子类进行大的更改？

Answer 1

您可以使用reintroduce添加新的重载方法.请注意,reintroduce; overload;子类中的顺序是必需的; 如果你反转它们,代码将无法编译.

TCParent = Class
private
public
 procedure SaveConfig; virtual; abstract;
end;

TCChild = Class(TCParent)
private
public
 procedure SaveConfig; overload; override;
 procedure SaveConfig(const FileName: string); reintroduce; overload;
end;

(在Delphi 7中测试过,所以应该在它和所有更高版本中使用.)

Answer 2

由于您不想对其他后代进行更改,我建议在父类中添加一个可选字段来保存参数,然后任何想要使用参数的后代都可以使用它们.这样,您就不必更改被覆盖的签名SaveConfig().例如:

type
  TCParent = class
  protected
    SaveConfigParams: TStrings; // or whatever...
  public
    procedure SaveConfig; overload; virtual; abstract;
    procedure SaveConfig(Params: TStrings); overload;
  end;

procedure TCParent.SaveConfig(Params: TStrings);
begin
  SaveConfigParams := Params;
  try
    SaveConfig;
  finally
    SaveConfigParams := nil;
  end;
end;

.

type
  TCChild = class(TCParent)
  public
    procedure SaveConfig; override;
  end;

procedure TCChild.SaveConfig;
begin
  if SaveConfigParams <> nil then
  begin
    // do something that uses the parameters...
  end else begin
    // do something else...
  end;
end;

.

type
  TCChild2 = class(TCParent)
  public
    procedure SaveConfig; override;
  end;

procedure TCChild2.SaveConfig;
begin
  // do something, ignoring the SaveConfigParams...
end;