如何在grails域类中设置默认值

Question

有没有办法为域类属性设置默认值？我有一个名为PayMethod的类,我希望'name'属性默认为'cash'.当我创建这个表时我想要这个默认值,这是否可以使用约束？

package abc

import util.UserUtil
import embed.AuditUser

class PayMethod {

    String name = "Cash"

    AuditUser audit = new AuditUser()
    static embedded = ['audit']    

    static constraints = {
        name blank: false, size: 5..30, unique: true
    }

    static mapping = {
        table 't01i0010'
        id column: 'F_ID', precision: 4, scale: 0
        name column: 'F_NAME', length: 30, defaultValue: 'Cash'
        version column: 'F_REVISION'
    }

    def authUserService
    int insertIndex = 0
    int updateIndex = 0
    static transients = ['authUserService', 'insertIndex', 'updateIndex']    

    def beforeInsert = {
        audit.entryUser = UserUtil.user()
        audit.entryDate = new Date();
    }

    def beforeUpdate = {
        audit.reviseUser = UserUtil.user()
        audit.reviseDate = new Date();
    }

    def afterInsert = {
        if(insertIndex == 0){
            def user = audit.entryUser
            def date = audit.entryDate
            log.info "POST INSERT => ENTERER: ${user} ENTERED: ${date}"
        }
        insertIndex++
    }

    def afterUpdate = {
        if(updateIndex == 0){
            def user = audit.reviseUser
            def date = audit.reviseDate
            log.info "POST UPDATE => REVISE: ${user} REVISED: ${date}"
        }
        updateIndex++
    }
}

Answer 1

这将在2.2中实现,应在本周或下周发布.有关相关功能请求,请参见http://jira.grails.org/browse/GRAILS-5520.语法将是

static mapping = {
   name defaultValue: "'Cash'"
}

现在你需要做你正在做的事情 - 将值设置为字段的默认值.您可以手动更新数据库架构,也可以在迁移过程中完成工作.

Answer 2

要构建上一个答案,您可以使用Grails 2.2中的defaultValue属性,但是您需要小心地将双引号和单引号放在String属性的默认值周围,并在整数属性周围使用双引号,以便在DDL中正确显示默认值.因此,例如,您需要使用:

static mapping = {
   myStringProperty defaultValue: "'Cash'"
   myIntProperty defaultValue: "0"
}

如果你只使用单引号,你最终会得到像"列"CASH"未找到"这样的错误.另外,据我所知,默认值不适用于枚举属性.