GLSL中的高效双立方过滤代码？

Question

我想知道是否有人有完整的,工作的和有效的代码来在glsl中进行双三次纹理过滤.有这样的:

http://www.codeproject.com/Articles/236394/Bi-Cubic-and-Bi-Linear-Interpolation-with-GLSL 或 https://github.com/visionworkbench/visionworkbench/blob/master/src/vw/ GPU /着色器/口译/插值bicubic.glsl

但是它们都进行了16次纹理读取,其中只需要4次:

https://groups.google.com/forum/#!topic/comp.graphics.api.opengl/kqrujgJfTxo

然而,上面的方法使用了一个缺少的"cubic()"函数,我不知道它应该做什么,还需要一个无法解释的"texscale"参数.

还有NVidia版本:

http://http.developer.nvidia.com/GPUGems2/gpugems2_chapter20.html

但我相信这会使用CUDA,这是专门针对NVidia的卡片.我需要glsl.

我可以将nvidia版本移植到glsl,但我想先问一下是否有人已经有一个完整的,工作的glsl bicubic着色器.

Answer 1

我决定花点时间挖掘我的旧Perforce活动,发现缺少的cubic()函数; 请享用!:)

vec4 cubic(float v)
{
    vec4 n = vec4(1.0, 2.0, 3.0, 4.0) - v;
    vec4 s = n * n * n;
    float x = s.x;
    float y = s.y - 4.0 * s.x;
    float z = s.z - 4.0 * s.y + 6.0 * s.x;
    float w = 6.0 - x - y - z;
    return vec4(x, y, z, w);
}

Answer 2

我发现这个实现可以用作texture()的替代品(来自http://www.java-gaming.org/index.php?topic=35123.0(一个错字修复)):

// from http://www.java-gaming.org/index.php?topic=35123.0
vec4 cubic(float v){
    vec4 n = vec4(1.0, 2.0, 3.0, 4.0) - v;
    vec4 s = n * n * n;
    float x = s.x;
    float y = s.y - 4.0 * s.x;
    float z = s.z - 4.0 * s.y + 6.0 * s.x;
    float w = 6.0 - x - y - z;
    return vec4(x, y, z, w) * (1.0/6.0);
}

vec4 textureBicubic(sampler2D sampler, vec2 texCoords){

   vec2 texSize = textureSize(sampler, 0);
   vec2 invTexSize = 1.0 / texSize;

   texCoords = texCoords * texSize - 0.5;


    vec2 fxy = fract(texCoords);
    texCoords -= fxy;

    vec4 xcubic = cubic(fxy.x);
    vec4 ycubic = cubic(fxy.y);

    vec4 c = texCoords.xxyy + vec2 (-0.5, +1.5).xyxy;

    vec4 s = vec4(xcubic.xz + xcubic.yw, ycubic.xz + ycubic.yw);
    vec4 offset = c + vec4 (xcubic.yw, ycubic.yw) / s;

    offset *= invTexSize.xxyy;

    vec4 sample0 = texture(sampler, offset.xz);
    vec4 sample1 = texture(sampler, offset.yz);
    vec4 sample2 = texture(sampler, offset.xw);
    vec4 sample3 = texture(sampler, offset.yw);

    float sx = s.x / (s.x + s.y);
    float sy = s.z / (s.z + s.w);

    return mix(
       mix(sample3, sample2, sx), mix(sample1, sample0, sx)
    , sy);
}

示例:最近的,双线性的,双三次的:

该图像的ImageData是

{{{0.698039, 0.996078, 0.262745}, {0., 0.266667, 1.}, {0.00392157, 
   0.25098, 0.996078}, {1., 0.65098, 0.}}, {{0.996078, 0.823529, 
   0.}, {0.498039, 0., 0.00392157}, {0.831373, 0.00392157, 
   0.00392157}, {0.956863, 0.972549, 0.00784314}}, {{0.909804, 
   0.00784314, 0.}, {0.87451, 0.996078, 0.0862745}, {0.196078, 
   0.992157, 0.760784}, {0.00392157, 0.00392157, 0.498039}}, {{1., 
   0.878431, 0.}, {0.588235, 0.00392157, 0.00392157}, {0.00392157, 
   0.0666667, 0.996078}, {0.996078, 0.517647, 0.}}}

我试图重现这个(许多其他插值技术)

但他们已经夹住了填充物,而我却重复(包裹)边界.因此它并不完全相同.

看起来这个双三次方的业务不是一个合适的插值,即它不会在定义数据的点处采用原始值.

Answer 3

缺少的功能cubic()在JAre的回答看起来是这样的:

vec4 cubic(float x)
{
    float x2 = x * x;
    float x3 = x2 * x;
    vec4 w;
    w.x =   -x3 + 3*x2 - 3*x + 1;
    w.y =  3*x3 - 6*x2       + 4;
    w.z = -3*x3 + 3*x2 + 3*x + 1;
    w.w =  x3;
    return w / 6.f;
}

它返回立方B样条的四个权重.

这一切都在NVidia Gems中进行了解释.

Answer 4

（编辑）

• Cubic() 是三次样条函数

例子：

• Texscale是采样窗口大小系数。您可以从 1.0 值开始。

vec4 filter(sampler2D texture, vec2 texcoord, vec2 texscale)
{
    float fx = fract(texcoord.x);
    float fy = fract(texcoord.y);
    texcoord.x -= fx;
    texcoord.y -= fy;

    vec4 xcubic = cubic(fx);
    vec4 ycubic = cubic(fy);

    vec4 c = vec4(texcoord.x - 0.5, texcoord.x + 1.5, texcoord.y -
0.5, texcoord.y + 1.5);
    vec4 s = vec4(xcubic.x + xcubic.y, xcubic.z + xcubic.w, ycubic.x +
ycubic.y, ycubic.z + ycubic.w);
    vec4 offset = c + vec4(xcubic.y, xcubic.w, ycubic.y, ycubic.w) /
s;

    vec4 sample0 = texture2D(texture, vec2(offset.x, offset.z) *
texscale);
    vec4 sample1 = texture2D(texture, vec2(offset.y, offset.z) *
texscale);
    vec4 sample2 = texture2D(texture, vec2(offset.x, offset.w) *
texscale);
    vec4 sample3 = texture2D(texture, vec2(offset.y, offset.w) *
texscale);

    float sx = s.x / (s.x + s.y);
    float sy = s.z / (s.z + s.w);

    return mix(
        mix(sample3, sample2, sx),
        mix(sample1, sample0, sx), sy);
}

来源

Answer 5

哇。我在2011年初提出上述代码时（我无法评论其信誉<50）。我要解决的问题与旧的IBM T42笔记本电脑有关（抱歉，确切的型号逃脱了我），它是ATI图形堆栈。我在NV卡上开发了代码，最初我使用了16次纹理获取。对于我而言，这有点慢，但足够快。当有人报告说无法在笔记本电脑上工作时，很明显他们不支持每个片段足够的纹理获取。我必须设计一种变通办法，而我能想到的最好的办法就是使用许多可行的纹理提取。

我是这样想的：好的，因此，如果我使用线性滤波器处理每个四边形（2x2），剩下的问题是行和列可以共享权重吗？这是我着手编写代码时唯一想到的问题。他们当然可以共享；每列和每一列的权重均相同；完善！

现在我有四个样本。剩下的问题是如何正确组合样本。那是要克服的最大障碍。用铅笔和纸花了大约10分钟。用颤抖的手，我输入了代码，它很好用。然后，我将二进制文件上传到一个答应要在他的T42（？）上进行检查的家伙，他报告说它可以工作。结束。:)

我可以确保方程式能够检出并给出数学上相同的结果，以便分别计算样本。仅供参考：使用CPU，分别进行水平和垂直扫描速度更快。使用GPU多遍并不是一个好主意，尤其是当在典型的用例中无论如何都不可行时。

值得深思：可以对cubic（）函数使用纹理查找。哪个更快取决于GPU，但通常来说，采样器在ALU方面比较轻便，只要进行算术运算就可以平衡一切。YMMV。