F#中的条件总和

Question

我已为F#中的某些客户端数据定义了记录类型,如下所示: -

  type DataPoint = {
       date: string; 
       dr: string; 
       Group: string; 
       Product: string; 
       Book: int; 
       Revenue: int} with 
          static member fromFile file =
               file
               |> File.ReadLines
               |> Seq.skip 1 //skip the header
               |> Seq.map (fun s-> s.Split ',') // split each line into array
               |> Seq.map (fun a -> {date = string a.[0]; dr = string a.[1];
                              Group = string a.[2]; Product = string a.[3];
                                Book = int a.[4]; Revenue = int a.[5] });;  

    // creates a record for each line
    let pivot (file) = DataPoint.fromFile file
              |> ??????????

对于date,dr,Group和Product都相等的行,我想对所有Book和Revenue条目求和,产生一个旋转的行.所以某种if else语句应该没问题.我怀疑我需要从第一个数据点开始并递归地添加每个匹配的行,然后删除匹配的行以避免输出中的重复.

完成此操作后,我将能够轻松地将这些旋转的行写入另一个csv文件.

谁能让我开始？

Answer 1

Seq.groupBy和Seq.reduce是您正在寻找的:

let pivot file = 
    DataPoint.fromFile file
    |> Seq.groupBy (fun dp -> dp.date, dp.dr, dp.Group, dp.Product)
    |> Seq.map (snd >> Seq.reduce (fun acc dp -> 
                          { date = acc.date; dr = acc.dr; 
                            Group = acc.Group; Product = acc.Product;
                            Book = acc.Book + dp.Book; 
                            Revenue = acc.Revenue + dp.Revenue; }))