Excel VBA 输入框 - 选择范围（类型 8）但不是固定范围，即 A1 不是 $A$1

Question

我目前在我的VBA代码中有以下行Inputbox：

Set myValues = Application.InputBox("Please select on the spreadsheet the first cell in the column with the values that you are looking for:", Type:=8)

但是，当我选择单元格时，它会自动输入例如$A$1. 这是否可以更改，而无需用户手动删除 $，以便Inputbox自动选择单元格引用为A1？

它是自动VLookup宏的一部分，除了VLookup整列中固定的值之外，它完美地工作。

提前致谢。

更新 - 这是完整的代码：

Dim FirstRow As Long
Dim FinalRow As Long
Dim myValues As Range
Dim myResults As Range
Dim myCount As Integer

Sub VlookupMacroNew()  

Set myValues = Application.InputBox("Please select on the spreadsheet the first cell in the column with the values that you are looking for:", Default:=Range("A1").Address(0, 0), Type:=8)

Set myResults = Application.InputBox("Please select on the spreadsheet the first cell where you want your lookup results to start:", Type:=8)

myCount = Application.InputBox("Please enter the column number of the destination range:", Type:=1)

On Error Resume Next
myResults.EntireColumn.Insert Shift:=xlToRight
Set myResults = myResults.Offset(, -1)
FirstRow = myValues.Row
FinalRow = Cells(65536, myValues.Column).End(xlUp).Row

Range(myResults, myResults.Offset(FinalRow - FirstRow)).Formula = _
"=VLOOKUP(" & Cells(FirstRow, myValues.Column).Address & ", " & _
"'S:\Payroll\CONTROL SECTION\[Latest Data.xls]Sheet1'!$A$1:$B$100" & ", " & myCount & ", False)"

myValues 将从例如单元格 A2 开始，但是当我们使用动态列表时，我需要将查找值更改为 A3、A4、A5 等，因为公式被复制到列表中。通过使用 $A$2 的输入框，查找公式仅查看该单元格引用。

Answer 1

正如蒂姆所说，你的问题不在于输入框。相反，当您一次为整个范围设置公式时，它会用于FirstRow每个单元格的公式。理想情况下，您可以用来.FormulaR1C1设置公式。这将允许您一次性使公式相对。

下面的解决方案只是修改您的代码以将非相对地址放入第一个单元格中，然后将其余单元格中的公式设置为等于第一个单元格中的公式。当您分配这样的公式时，它们就会变得相对：

Sub VlookupMacroNew()

Set myValues = Application.InputBox("Please select on the spreadsheet the first cell in the column with the values that you are looking for:", Default:=Range("A1").Address(0, 0), Type:=8)
Set myResults = Application.InputBox("Please select on the spreadsheet the first cell where you want your lookup results to start:", Type:=8)
myCount = Application.InputBox("Please enter the column number of the destination range:", Type:=1)

On Error Resume Next
myResults.EntireColumn.Insert Shift:=xlToRight
Set myResults = myResults.Offset(, -1)
FirstRow = myValues.Row
FinalRow = Cells(65536, myValues.Column).End(xlUp).Row

Range(myResults, myResults.Offset(FinalRow - FirstRow)).Cells(1).Formula = _
"=VLOOKUP(" & Cells(FirstRow, myValues.Column).Address(False, False) & ", " & _
"'S:\Payroll\CONTROL SECTION\[Latest Data.xls]Sheet1'!$A$1:$B$100" & ", " & myCount & ", False)"
Range(myResults, myResults.Offset(FinalRow - FirstRow)).Formula = _
Range(myResults, myResults.Offset(FinalRow - FirstRow)).Cells(1).Formula
End Sub