是否可以在遍历NERDTree时查看文件内容？

Question

我可以遍历NERDTree,但要查看文件内容,我按下去,一旦打开文件的缓冲区保持打开,直到我明确地关闭它.这使得查看文件太不舒服了.

当我遍历NERDTree节点时,我希望在临时查看器缓冲区中看到突出显示的文件内容,并且我想明确地选择一些遍历的文件进行编辑,比如按e.

当我关闭NERDTree缓冲区时,临时查看器缓冲区也将关闭,并且应该只为那些明确选择的文件打开缓冲区,而不是所有查看的文件.

那可能吗？

Answer 1

看起来这可能是NERDTree的一个很好的功能请求:)

同时,您可以在〜/ .vimrc中输入如下内容:

let g:nerd_preview_enabled = 0
let g:preview_last_buffer  = 0

function! NerdTreePreview()
  " Only on nerdtree window
  if (&ft ==# 'nerdtree')
    " Get filename
    let l:filename = substitute(getline("."), "^\\s\\+\\|\\s\\+$","","g")

    " Preview if it is not a folder
    let l:lastchar = strpart(l:filename, strlen(l:filename) - 1, 1)
    if (l:lastchar != "/" && strpart(l:filename, 0 ,2) != "..")

      let l:store_buffer_to_close = 1
      if (bufnr(l:filename) > 0)
        " Don't close if the buffer is already open
        let l:store_buffer_to_close = 0
      endif

      " Do preview
      execute "normal go"

      " Close previews buffer
      if (g:preview_last_buffer > 0)
        execute "bwipeout " . g:preview_last_buffer
        let g:preview_last_buffer = 0
      endif

      " Set last buffer to close it later
      if (l:store_buffer_to_close)
        let g:preview_last_buffer = bufnr(l:filename)
      endif
    endif
  elseif (g:preview_last_buffer > 0)
    " Close last previewed buffer
    let g:preview_last_buffer = 0
  endif
endfunction

function! NerdPreviewToggle()
  if (g:nerd_preview_enabled)
    let g:nerd_preview_enabled = 0
    augroup nerdpreview
      autocmd!
      augroup END
  else
    let g:nerd_preview_enabled = 1
    augroup nerdpreview
      autocmd!
      autocmd CursorMoved * nested call NerdTreePreview()
    augroup END
  endif
endfunction

这可能是非常天真和讨厌的代码,但通过一些调整可以做你打算做的事情.

编辑,版本2中的更改:

• 添加嵌套在自动命令上,因此语法高亮显示起作用
• 默认情况下不启用,执行:调用NerdPreviewToggle()以启用/禁用