Emacs中的缓冲区本地覆盖次模式键绑定

Question

我想使用一个次要模式,它重新绑定一个我绝对想要保留的主模式键.如何重新绑定密钥而不将其从全局的次模式映射中删除？我知道我可以使用define-key它,但我想保持其他缓冲区/主要模式的绑定.

有人可以帮忙吗？

Answer 1

做起来有点麻烦.你可以这样做:

(add-hook '<major-mode>-hook
  (lambda ()
    (let ((oldmap (cdr (assoc '<minor-mode> minor-mode-map-alist)))
          (newmap (make-sparse-keymap)))
      (set-keymap-parent newmap oldmap)
      (define-key newmap [<thekeyIwanttohide>] nil)
      (make-local-variable 'minor-mode-overriding-map-alist)
      (push `(<minor-mode> . ,newmap) minor-mode-overriding-map-alist))))

Answer 2

这是一个处理所有繁琐位的函数.

(defun local-set-minor-mode-key (mode key def)
  "Overrides a minor mode keybinding for the local
   buffer, by creating or altering keymaps stored in buffer-local
   `minor-mode-overriding-map-alist'."
  (let* ((oldmap (cdr (assoc mode minor-mode-map-alist)))
         (newmap (or (cdr (assoc mode minor-mode-overriding-map-alist))
                     (let ((map (make-sparse-keymap)))
                       (set-keymap-parent map oldmap)
                       (push `(,mode . ,map) minor-mode-overriding-map-alist) 
                       map))))
    (define-key newmap key def)))

此后你可以做到

(local-set-minor-mode-key '<minor-mode> (kbd "key-to-hide") nil)