删除多行注释

Question

如果它们以/*开头并以*结尾,我如何删除所有注释？我尝试了以下操作.它适用于一行评论.

sed '/\/\*/d' 

但它不会删除多行注释.例如,不删除第二行和第三行.

/*!50500 PARTITION BY RANGE (TO_SECONDS(date_time ))
 PARTITION 20120102parti VALUES LESS THAN (63492681600),
(PARTITION 20120101parti VALUES LESS THAN (63492595200) */ ;

在上面的例子中,我需要保留最后一个; 在结束评论标志后.

Answer 1

这是使用的一种方式GNU sed.跑得像sed -rf script.sed file.txt

内容script.sed:

:a
s%(.*)/\*.*\*/%\1%
ta
/\/\*/ !b
N
ba

或者,这是一个班轮:

sed -r ':a; s%(.*)/\*.*\*/%\1%; ta; /\/\*/ !b; N; ba' file.txt

Answer 2

如果这是在C文件中,那么你必须使用C预处理器与其他工具结合使用来暂时禁用特定的预处理器功能,如扩展#defines或#includes,所有其他方法在边缘情况下都会失败.这适用于所有情况:

[ $# -eq 2 ] && arg="$1" || arg=""
eval file="\$$#"
sed 's/a/aA/g; s/__/aB/g; s/#/aC/g' "$file" |
          gcc -P -E $arg - |
          sed 's/aC/#/g; s/aB/__/g; s/aA/a/g'

将它放在shell脚本中,并使用您要解析的文件的名称调用它,可选择使用"-ansi"之类的标记作为前缀,以指定要应用的C标准.

Answer 3

这应该做

 sed 's|/\*|\n&|g;s|*/|&\n|g' a.txt | sed '/\/\*/,/*\//d'

测试:

A.TXT

/* Line test
multi
comment */
Hello there
this would stay 
/* this would be deleteed */

命令:

$ sed 's|/\*|\n&|g;s|*/|&\n|g' a.txt | sed '/\/\*/,/*\//d'
Hello there
this would stay