在AS3中将alpha百分比转换为RGBA hex？

Question

假设我的AS代码中有以下设置:

var color:String = "#0000FF"; //blue
var alpha:Number = 42; //42% or 42/100

我如何将它们组合成#RRGGBBAA十六进制颜色？我一直在谷歌搜索并试图找出十六进制转换和符号没有运气.

Answer 1

有两种方法可以做到这一点.一个是hacky使用int的toString()方法并传递16作为基数/基数:

var rgb:int = (int)("#0000FF".replace("#","0x"));//convert the string to a int (note you can type hex ints starting with 0x (e.g. 0x0000FF)
var a:int = 42;
var rgba:int = int("0x"+rgb.toString(16) + a.toString(16));

或使用按位运算符的较少hacky和可能更快的计算方法:

var rgb:uint = (uint)("#0000FF".replace("#","0x"));
//extract components using bit shifting (>>) and masking (0xFF)
var r:uint = rgb >> 16 & 0xFF;
var g:uint = rgb >>  8 & 0xFF;
var b:uint = rgb >>  0 & 0xFF;//same as rgb >> 0xFF, just added >> 0 to make the shift obvious
var a:uint = 42;
var rgba:uint = r << 24 | g << 16 | b << 8 | a;
var argb:uint = a << 24 | r << 16 | g << 8 | b;
//test
trace(rgba.toString(16));
trace(argb.toString(16));

请注意,toString(16)在上面的跟踪中使用是为了使它对我们人类有用,在使用十六进制颜色值时,您将使用实际的uint值.

另请注意,有时您可能希望在as3中使用ARGB,例如在使用BitmapData时:

addChild(new BitmapData(100,100,true,0x2a0000ff));//add a 42% transparent blue box (100x100 px)

UPDATE

上面的bithift代码片段实际上详细解释了rgb提取,这有助于更好地理解事物,但是你已经有了rgb,所以这是添加alpha组件的问题.你也提到了42%,它与0到255的刻度不同.因此,吼叫是你的答案:

var rgb:uint = (uint)("#0000FF".replace("#","0x"));
var   a:uint = (uint)((42 * .01) * 255);//map 42 from 0<>100 to 0<>255 ( *.01 is the same as / 100 but faster
var rgba:uint = rgb << 8 | a;
var argb:uint = a << 24 | rgb;

关于速度,如果我运行两种不同的转换方法,这里的执行时间是一百万次:

using strings (var rgba:int = int("0x"+rgb.toString(16) + a.toString(16));) takes 851 ms 
using bitwise ops (var rgba:uint = rgb << 8| a;) takes 3 ms

正如您所能,按位版本更快,对于您的情况甚至比字符串版本更简洁.此外,现在你理解按位运算符可能更容易阅读/理解.

结论:

var color:String = "#0000FF"; //blue
var alpha:Number = 42; //42% or 42/100
var rgb:uint = (uint)(color.replace("#","0x"));
var   a:uint = (uint)((alpha * .01) * 255);
var rgba:uint = rgb << 8 | a;
trace("hex: #",rgba.toString(16),"test",0x0000ff6b.toString(16));

此外,你提到谷歌很有趣,因为你可以使用搜索转换为十六进制.

更新:似乎有点混乱,所以我将3个步骤分成了几个功能:

1. 将十六进制字符串转换为int
2. 将alpha百分比(0-100)转换为0-255 int
3. 连接上面的

这将是:

function getHex(hexStr:String):uint{
    return (uint)(hexStr.replace("#","0x"));
}
function getHexAlpha(alpha:uint):uint{
    return (uint)((alpha * .01) * 255);
}
function rgbaConcat(rgb:uint,a:uint):uint{
    return rgb << 8 | a;
}
trace("test",rgbaConcat(getHex("#FF9900"),getHexAlpha(50)).toString(16));

或者一气呵成:

function rgbaConcat(hexStr:String,alpha:uint):uint{
    var rgb:uint = (uint)(hexStr.replace("#","0x"));
    var a:uint = (uint)((alpha * .01) * 255);
    return (rgb << 8 | a);
}
trace("test",rgbaConcat("#123456",100).toString(16));