如何使用Perl将文件中的CSS定义合并到内联样式属性？

Question

许多电子邮件客户端不喜欢挂CSS样式表,甚至嵌入式<style>标签,而是要作为风格上的所有标记属性的CSS内联出现.

• 坏: <link rel=stylesheet type="text/css" href="/style.css">
• 坏: <style type="text/css">...</style>
• 作品: <h1 style="margin: 0">...</h1>

然而,这种内联样式属性方法是一种正确的管理方法.

我找到了Ruby和PHP的工具,它们将CSS文件和一些单独的标记作为输入,并返回合并结果 - 一个标记文件,所有CSS转换为样式属性.

我正在寻找这个问题的Perl解决方案,但我没有在CPAN或搜索Google上找到它.有什么指针吗？或者,是否有CPAN模块可以组合以实现相同的结果？

• Ruby http://premailer.dialect.ca/
• PHP http://www.pelagodesign.com/sidecar/emogrifier/
• Perl？

Answer 1

我不知道一个完整的,预先打包的解决方案.

CSS :: DOM的compute_style是受到几乎相同的警告作为emogrifier以上.该模块与HTML :: TokeParser一起应该可用于烹饪.

更新:这是一个错误的混合物:

#!/usr/bin/perl

use strict;
use warnings;

use CSS::DOM;
use File::Slurp;
use HTML::DOM;
use HTML::TokeParser;

die "convert html_file css_file" unless @ARGV == 2;
my ($html_file, $css_file) = @ARGV;

my $html_parser = HTML::TokeParser->new($html_file)
    or die "Cannot open '$html_file': $!";

my $sheet = CSS::DOM::parse( scalar read_file $css_file );

while ( my $token = $html_parser->get_token ) {
    my $type = $token->[0];
    my $text = $type eq 'T' ? $token->[1] : $token->[-1];
    if ( $type eq 'S' ) {
        unless ( skip( $token->[1] ) ) {
            $text = insert_computed_style($sheet, $token);
        }
    }
    print $text;
}

sub insert_computed_style {
    my ($sheet, $token) = @_;
    my ($tag, $attr, $attrseq) = @$token[1 .. 3];
    my $doc = HTML::DOM->new;

    my $element = $doc->createElement($tag);

    for my $attr_name ( @$attrseq ) {
        $element->setAttribute($attr_name, $attr->{$attr_name});
    }

    my $style = CSS::DOM::compute_style(
        element => $element, user_sheet => $sheet
    );

    my @attrseq = (style => grep { lc $_ ne 'style' } @$attrseq );
    $attr->{style} = $style->cssText;

    my $text .= join(" ",
        "<$tag",
        map{ qq/$_='$attr->{$_}'/ } @attrseq );
    $text .= '>';

    return $text;
}

sub skip {
    my ($tag) = @_;
    $tag = lc $tag;
    return 1 if $tag =~ /^(?:h(?:ead|tml)|link|meta|script|title)$/;
}

Answer 2

您可以使用 CPAN Perl 模块CSS::Inliner https://metacpan.org/release/CSS-Inliner