zsh preexec命令修改

Question

有没有办法修改即将执行的命令？我想将输出重定向到文件,并将其打印在终端上.我找到了ls > file.txt | cat这个工作,所以我想将它添加> file.txt | cat到任何即将执行的命令中.
有没有更好的方法重定向到文件并打印到终端？我正在尝试制作记录器.

Answer 1

您可以更改执行行时执行的操作以更改将要执行的命令.这可以通过定义一个函数然后绑定到回车键来完成.

让我们首先定义一个可以添加'> file.txt |的函数 cat'结束任何命令:

function log_and_accept {
    BUFFER="$BUFFER > file.txt | cat"
    zle accept-line
}

下一部分是用新函数实际替换默认的回车键行为.我们要替换的默认行为是accept-line函数,如果我们查看zle文档,您将看到accept-line绑定到^ J和^ M.

要将此函数绑定到这些字母,首先需要将其转换为小部件:

zle -N log_and_accept_widget log_and_accept

然后你可以绑定它,替换旧的行为:

bindkey '^J' log_and_accept_widget
bindkey '^M' log_and_accept_widget

现在,您将针对您执行的每个命令扩展该命令.每个cd,ls,vim等等.因此我建议你定义一些实际上打开和关闭它的功能:

function turn_on_logging {
    bindkey '^J' log_and_accept_widget
    bindkey '^M' log_and_accept_widget
}
function turn_off_logging {
    bindkey '^J' accept-line
    bindkey '^M' accept-line
}

zle -N turn_on_logging_widget turn_on_logging
zle -N turn_off_logging_widget turn_off_logging

bindkey '^P' turn_on_logging_widget
bindkey '^O' turn_off_logging_widget

我想你应该小心这一点.经过一段时间的测试后,我很快就开始不喜欢它了.

Answer 2

有几种方法可以做到这一点，我最喜欢的 1 是我在这里找到的这个块http://git.grml.org/?p=grml-etc-core.git;a=blob_plain;f=etc/zsh /zshrc;hb=HEAD

abk=(
  '...'  '../..'
  '....' '../../..'
  'BG'   '& exit'
  'C'    '| wc -l'
  'G'    '|& grep '${grep_options:+"${grep_options[*]}"}
  'H'    '| head'
  'Hl'   ' --help |& less -r'    #d (Display help in pager)
  'L'    '| less'
  'LL'   '|& less -r'
  'M'    '| most'
  'N'    '&>/dev/null'           #d (No Output)
  'R'    '| tr A-z N-za-m'       #d (ROT13)
  'SL'   '| sort | less'
  'S'    '| sort -u'
  'T'    '| tail'
  'V'    '|& vim -'
  'co'   './configure && make && sudo make install'
  'fc'   '> file.txt | cat'
)

zleiab() {
  emulate -L zsh
  setopt extendedglob
  local MATCH

  if (( NOABBREVIATION > 0 )) ; then
      LBUFFER="${LBUFFER},."
      return 0
  fi

  matched_chars='[.-|_a-zA-Z0-9]#'
  LBUFFER=${LBUFFER%%(#m)[.-|_a-zA-Z0-9]#}
  LBUFFER+=${abk[$MATCH]:-$MATCH}
}

zle -N zleiab && bindkey ",." zleiab

另请注意，我已添加'fc' '> file.txt | cat'到列表中abk

它的作用是，您fc在命令后键入，然后,.快速连续地敲击（逗号和句点），zsh 将替换fc为> file.txt | cat