循环字符串替换的批处理文件

Question

我有一个批处理文件,它将目录路径作为参数.

在该文件夹中,我需要转换为jpg的任意数量的.ai.pdf或.pdf文件.转换不是我的问题(我正在使用imageMagick),但删掉完整的扩展名是.

我需要能够从文件名中取出完整的.ai.pdf(7个字符)或.pdf(4个字符)并将其替换为.jpg我不能在for循环中使用~n因为它不会在一个实例中取出.ai.有一个.ai.pdf(结果是文件名.我只需要文件名)

关于此StackOverFlow示例,StackOverFlow上有相当多的帖子

但无论我尝试尝试什么,我都会在截断文件名的适当数量的扩展名时出错.

这是我的代码.这是我创建的第一个主要批处理文件,所以除了安装更多程序以完成工作外,我对任何事情都持开放态度.

杀死我的是,我有这个工作,从一个服务器到另一个服务器的洗牌和一个星期的休假,工作代码......错位了.

@echo off
SETLOCAL ENABLEDELAYEDEXPANSION
set dir1=%1
echo recieved !dir1!
for /R %dir1% %%a in (*.pdf) DO ( 
  echo file found !a!
  set b=th_%%~nxa
  if x%b:ai.pdf=%==x%b% set b=%%~dpa!b:~0,-7!
  if not x%b:ai.pdf=%==x%b% set b=%%~dpa!b:~0,-4!

  REM convert -density 64 "%%a" +matte -resize 15%% "!b!.jpg"
  @echo !b! converted
)

ENDLOCAL

该文件告诉我 %~dpa!b:~0,-7!是无效的替代

有任何想法吗？谢谢您的帮助!

Answer 1

先做几件事:

!a!并且%%a是两个不同的变量.

if x%b:ai.pdf=%==x%b%并不意味着你的想法.当这只会是真的%b%不不包含.ai.pdf.

同样,if not x%b:ai.pdf=%==x%b%并不代表你的想法.当%b% DOES包含时,这是真的.ai.pdf.

无需进行任何验证和切割,只需搜索和替换即可.(这是什么%y:x=z%符号呢,在这个例子中它替换每个x内%y%用z.)让搜索和替换做验证.它只会替换匹配搜索的内容.这将加快您的批处理文件.

最后,由于您位于()代码块内,因此您需要在setlocal语句中使用延迟扩展.这是因为代码块中的所有内容都被视为在一行上.这意味着如果更改代码块中的变量,您将无法使用%表示法查看新值.相反,你需要替换%'s !'.例如...

setlocal enableDelayedExpansion
set x=Hello
(
  set x=Goodbye
  echo I don't know why you say "!x!", I say "%x%".
)

...会给你旧披头士歌词...

I don't know why you say "Goodbye", I say "Hello".

无论如何,你的回答:

@echo off
SETLOCAL ENABLEDELAYEDEXPANSION
set dir1=%1
echo recieved !dir1!
for /R %dir1% %%a in (*.pdf) DO ( 
  :: Adding a colon to the end of the filename allows the extension to be ID'd
   : without explicitly looking at it with an IF statement, while simultaneously
  :: avoiding similar looking character groupings inside the filename.
  set b=th_%%~nxa:
  :: No need to check for case, the substitution will do that for you.
  set b=!b:.ai.pdf:=.jpg!
  set b=!b:.pdf:=.jpg!

  REM convert -density 64 "%%a" +matte -resize 15%% "!b!"
  echo %%a converted into !b!
)

ENDLOCAL

缺点是两个文件......

X.ai.pdf
X.pdf

...将被翻译成th_X.jpg两个不同文件的重复文件名的可能性.

但是,这对于将两种类型的文件名视为相同的概念是固有的.如果你没有避免这种重复的方法,那么.ai将文件留在文件上可能并不是一个坏主意,从而创建了两个文件:th_X.jpg并且th_X.ai.jpg消除了重复文件名的可能性.