如何创建批处理文件以创建网页的快捷方式

Question

我想创建一个批处理文件,在桌面或开始菜单中创建快捷方式.

快捷方式需要打开一个本地Windows服务器IP地址的网页(如'http:\ 192.168 ... *:81 \').

我还想为快捷方式提供自定义图像图标.

Answer 1

我知道这是一个旧线程,但它是第一个在Google中弹出的StackOverFlow页面,所以我想我会做出回复.

以下是我用来管理URL快捷方式的批处理脚本:(请注意,此脚本假定图标也存在 - MyIconName.ico - 与此脚本位于同一目录中.如果图标不可用或不需要,只需省略相关的行)

请注意,任何尾随空格都会影响变量的值......

@echo off 
@echo. 
@echo.
@echo.

::Set the application-specific string vars 
SET AppDescription=MyAppName
SET IconName=MyIconName.ico
SET Shortcut_Name=MyShortcutName.url
SET URL_PATH=http://www.Google.com

::Set the common string vars 
SET WORKING_PATH=%~dp0
SET ICONDEST=c:\ProgramData\%AppDescription%
SET LinkPath=%userprofile%\Desktop\%Shortcut_Name%

@echo. Copy Icon 
IF EXIST "%ICONDEST%" (GOTO _CopyIcon) 
mkdir "%ICONDEST%"
:_CopyIcon 
copy "%WORKING_PATH%%IconName%" "%ICONDEST%"

echo. 
echo. Create desktop shortcut... 
echo [InternetShortcut] > "%LinkPath%"
echo URL=%URL_PATH% >> "%LinkPath%"
echo IDList= >> "%LinkPath%"
echo IconFile=%ICONDEST%\%IconName% >> "%LinkPath%"
echo IconIndex=0 >> "%LinkPath%"
echo HotKey=0 >> "%LinkPath%"
echo. 
echo. 
echo. 
echo. 
echo.You should now have a shortcut to %AppDescription% on your desktop... 
echo. 
echo. 
pause