使用DAO和Sql Server链接表的事务

Question

我正在将一个clasic Access应用程序迁移到Sql Server,即DAO + Linked表.

我发现了一个令人反感的行为:当我使用链接表上的记录集进行更改时,Access使用多个连接.多个连接在服务器端同时意味着多个事务.这些交易是独立的.没有嵌套.

使用链接表到.mdb文件的标准MS-Access行为是不同的.一次只有一笔交易.执行提交之前,在同一DAO.Workspace中运行的任何代码都可以看到每个数据库更改.

规则已更改,使用客户端事务的现有DAO代码将失败.

如果我使用打开为dbOpenDynaset的记录集添加或更新记录,则任何尝试读取它们的代码都将失败:找不到新记录并查看原始状态的现有记录.为什么？因为操作是在多个独立的交易中进行的

执行示例提供的代码,sql profiler将向您显示使用不同的事务ID进行的不同操作.

我已经使用ADO对此进行了测试,一切运行良好.但是有成千上万的代码行.

除了使用ADO重写代码之外,还有其他解决方案吗？

我可以修改标准的Access行为吗？(使用读取未提交的隔离级别,指示不打开新连接,...)

下面的代码重现了这个问题.这很简单:

1.-在现有记录上打开记录集
2.-添加新记录
3.-尝试阅读最近添加的记录

如果我在(1)中使用dbOpenDynaset,我将看不到(3)中的新记录.

我正在使用Acc-2010,.accdb格式文件和Sql Server 2008 R2

谢谢.

    Private Sub test0()
     Dim bResult As Boolean

    Dim bUseTrans As Boolean 'New record added in transaction

    Dim rsExist As DAO.Recordset2 'Dummy recordset
     Dim tRecordsetExist As DAO.RecordsetTypeEnum 'Dummy recordset type:
                                                  '  with dbOpenDynaset fail.
                                                  '  Any other works fine

    Dim rs2Add As DAO.Recordset

    Dim rs2Read As DAO.Recordset 'Used to read recently added record
     Dim tRecordset2Read As DAO.RecordsetTypeEnum 'Recordset type used to read new record. Doesn't affect

    Dim bTranInitiated As Boolean 'Track if we are in transaction

    Dim lngExistingNumber As Long
     Dim lngNewNumber As Long
     Dim lngNewID As Long
     Dim strSQL As String
 On Error GoTo HandleErr

    'Invoices table definition in SS. Table is linked as [dbo_Invoices]:
     '   CREATE TABLE [dbo].[Invoices](
     '       [IdInvoice] [int] IDENTITY(1,1) NOT NULL,
     '       [InvoiceNumber] [int] NOT NULL,
     '       [InvoiceDescription] [varchar](50) NOT NULL,
     '    CONSTRAINT [PK_Invoices] PRIMARY KEY CLUSTERED
     '   (
     '       [IdInvoice] Asc
     '   )WITH (PAD_INDEX  = OFF, STATISTICS_NORECOMPUTE  = OFF, IGNORE_DUP_KEY = OFF, ALLOW_ROW_LOCKS  = ON, ALLOW_PAGE_LOCKS  = ON) ON [PRIMARY]
     '   ) ON [PRIMARY]

    Set wks = DBEngine.Workspaces(0)
     Set dbs = wks.Databases(0)

    bUseTrans = True 'Without transaction everything works well

    tRecordsetExist = dbOpenDynaset 'Dummy recordset type:
                                     '  dbOpenDynaset makes fail.
                                     '  Any other works fine

    tRecordset2Read = dbOpenForwardOnly 'Does not affect

    lngExistingNumber = 12001
     lngNewNumber = -lngExistingNumber

    'Clean previous runs of the test and make sure that referenced invoice exists.
     dbs.Execute "Delete from dbo_Invoices Where InvoiceNumber = " & lngNewNumber, dbFailOnError Or dbSeeChanges
     On Error Resume Next
     strSQL = "Insert Into dbo_Invoices (InvoiceNumber, InvoiceDescription) " & _
             " Values (" & lngExistingNumber & ", 'Original invoice' )"
     dbs.Execute strSQL, dbFailOnError Or dbSeeChanges
     On Error GoTo HandleErr

    If bUseTrans Then
         wks.BeginTrans
         bTranInitiated = True
     End If

    strSQL = "Select IdInvoice, InvoiceNumber from dbo_Invoices " & _
             " Where InvoiceNumber = " & lngExistingNumber
     If tRecordsetExist = dbOpenDynaset Then
         Set rsExist = dbs.OpenRecordset(strSQL, dbOpenDynaset, dbSeeChanges)
     Else
         Set rsExist = dbs.OpenRecordset(strSQL, tRecordsetExist)
     End If
     If rsExist.BOF And rsExist.EOF Then
         Err.Raise vbObjectError, , "Original invoice " & lngExistingNumber & " not found"
     End If

    Set rs2Add = dbs.OpenRecordset("Select * from dbo_Invoices", dbOpenDynaset, dbAppendOnly Or dbSeeChanges)

    rs2Add.AddNew
     rs2Add!InvoiceNumber = lngNewNumber
     rs2Add!InvoiceDescription = "Invoice anulation, ref " & lngExistingNumber
     rs2Add.Update

    'After executing .Update rs2Add goes to .EOF. This action reposition the recordset on the new record
     rs2Add.Move 0, rs2Add.LastModified

    lngNewID = rs2Add!IdInvoice
     Debug.Print "New record added: IdInvoice = " & rs2Add!IdInvoice & ", InvoiceNumber = " & rs2Add!InvoiceNumber

    'Try to read the new record
     strSQL = "Select * from dbo_Invoices Where IdInvoice = " & lngNewID
     If tRecordset2Read = dbOpenDynaset Then
         Set rs2Read = dbs.OpenRecordset(strSQL, dbOpenDynaset, dbSeeChanges)
     Else
         Set rs2Read = dbs.OpenRecordset(strSQL, tRecordset2Read)
     End If
     If (rs2Read.BOF And rs2Read.EOF) Then
         Err.Raise vbObjectError, , "rs2Read: Not found using IdInvoice = " & lngNewID
     End If
     Debug.Print "New record found with IdInvoice = " & rs2Read!IdInvoice
     rs2Read.Close

    bResult = True
 ExitHere:
     If Not wks Is Nothing Then
         If bTranInitiated Then
             If bResult Then
                 wks.CommitTrans
             Else
                 wks.Rollback
             End If
             bTranInitiated = False
         End If
     End If
     On Error Resume Next
     If Not rs2Add Is Nothing Then
         rs2Add.Close
         Set rs2Add = Nothing
     End If
     If Not rs2Read Is Nothing Then
         rs2Read.Close
         Set rs2Read = Nothing
     End If
     Exit Sub
 HandleErr:
     Dim e As Object
     If Err.Description Like "ODBC*" Then
         For Each e In DBEngine.Errors
             MsgBox e.Description, vbCritical
         Next
     Else
         MsgBox Err.Description, vbCritical
     End If
     bResult = False
     Resume ExitHere
     Resume
 End Sub

Answer 1

不幸的是，微软对财产有以下规定Workspace.IsolateODBCTrans： http://msdn.microsoft.com/en-us/library/office/bb208483 (v=office.12).aspx

某些 ODBC 服务器（例如 Microsoft SQL Server）不允许在单个连接上同时进行事务处理。如果您需要一次针对此类数据库有多个待处理事务，请在打开每个工作区后立即将其上的 IsolateODBCTrans 属性设置为 True。这会强制为每个工作区建立单独的 ODBC 连接。

不确定这是否会帮助您决定要做什么。