上周一和上周日基于今天的日期

Question

我需要正确的语法来给我:

1. 前几周星期一根据当前日期/时间使用日期 GETDATE()
2. 前几周的星期日日期基于当前使用的日期/时间 GETDATE()

所以,基于今天的日期(14/09/2012),我想要以下内容:

1. 上周一日期= 03/09/2012
2. 上周日日期= 09/09/2012

Answer 1

简单:

--start of last week
SELECT DATEADD(wk, DATEDIFF(wk, 6, GETDATE()), 0)

--end of last week
SELECT DATEADD(wk, DATEDIFF(wk, 6, GETDATE()), 6)

编辑:

以下将处理星期日发布日期.

DECLARE @input varchar(10)
--SET @input = '9/9/2012' -- simulates a Sunday
SET @input = GETDATE()

--start of last week
SELECT DATEADD(wk, DATEDIFF(wk, 6, 
CASE DATEPART(dw,@input)
WHEN 1 THEN DATEADD(d,-1,@input)
ELSE @input
END
), 0)

--end of last week
SELECT DATEADD(wk, DATEDIFF(wk, 6, 
CASE DATEPART(dw,@input)
WHEN 1 THEN DATEADD(d,-1,@input)
ELSE @input
END
), 6)

Answer 2

上周一：

SELECT DATEADD(DD,-(DATEPART(WEEKDAY, GETDATE())+5)%7, GETDATE())

上周日：

SELECT DATEADD(DD,-(DATEPART(WEEKDAY, GETDATE())+6)%7, GETDATE())

Answer 3

除了使用案例选项,您还可以执行此操作以获取当前周的周日:

SELECT DATEADD(dd, DATEPART(DW,GETDATE())*-1+1, GETDATE())

要获得前一周的周日,再减去7天:

SELECT DATEADD(dd, DATEPART(DW,GETDATE())*-1-6, GETDATE())

Answer 4

我认为这是更干净的解决方案：

SELECT
    -- 17530101 or 1753-01-01 is the minimum date in SQL Server
    DATEADD(dd, ((DATEDIFF(dd, '17530101', GETDATE()) / 7) * 7) - 7, '17530101') AS [LowerLimit], -- Last Week's Monday
    DATEADD(dd, ((DATEDIFF(dd, '17530101', GETDATE()) / 7) * 7) - 1, '17530101') AS [UpperLimit] -- Last Week's Sunday.

在现实世界的查询中可以这样使用：

SELECT
    *
FROM
    SomeTable
WHERE
    SomeTable.[Date] >= DATEADD(dd, ((DATEDIFF(dd, '17530101', GETDATE()) / 7) * 7) - 7, '17530101') AND
    SomeTable.[Date] <= DATEADD(dd, ((DATEDIFF(dd, '17530101', GETDATE()) / 7) * 7) - 1, '17530101')

以下是一些测试：

1. 闰年

当前日期：2016-02-29 00:00:00.000

结果：

LowerLimit                 UpperLimit
2016-02-22 00:00:00.000    2016-02-28 00:00:00.000

2. 上周是不同年份

当前日期：2016-01-06 00:00:00.000

LowerLimit                 UpperLimit
2015-12-28 00:00:00.000    2016-01-03 00:00:00.000

3、上月下限、当月上限

当前日期：2016-05-04 00:00:00.000

LowerLimit                 UpperLimit
2016-04-25 00:00:00.000    2016-05-01 00:00:00.000

4. 当前日期是星期日

当前日期：2016-05-08 00:00:00.000

LowerLimit                 UpperLimit
2016-04-25 00:00:00.000    2016-05-01 00:00:00.000

Answer 5

更好的是，我认为，这适用于任何日期，任何工作日，任何 DateFirst 参数（设置一周的第一天，在法国通常为 1-星期一，默认为 7-星期日）。

create function [dbo].[previousWeekDayDate](@anyDate date, @anyWeekDay int)
returns Date
as
begin
    return DATEADD(dd, ((DATEPART(dw,@anyDate) + @@DateFirst - @anyWeekDay + 13) % 7) * -1, @anyDate)
end

适用于 SQL 2008，创建函数并使用：

SELECT dbo.previousWeekDayDate(GetDate(),1) --for Monday
SELECT dbo.previousWeekDayDate(GetDate(),7) --for Sunday