AS3:将MovieClip保持在最顶层

Question

所以这有点难以解释,我会尽我所能,但请耐心等待我.

好.所以我正在创建一个涉及道路的游戏,并且汽车随机地移动它(每隔5秒左右)

我使用下面的代码来创建汽车及它们应该移动的方向,并在屏幕上完成补间后删除.

 public function animateCars()
    {
        CarMC = Random_Car();

        if (CarLeft)
        {
            CarMC.x = 0;
            CarMC.y = 245;
            CarMC.name = "CarNumber_"+CarNumber;
            addChildAt(CarMC,numChildren - 1);
            MoveCar = new Tween(CarMC,"x",None.easeNone,-60,900,12,true);
            MoveCar.addEventListener(TweenEvent.MOTION_FINISH, CarFinished);
            MoveCar.start();
        }
        else
        {
            CarMC.x = 0;
            CarMC.y = 258;
            CarMC.name = "CarNumber_"+CarNumber;
            CarMC.scaleX *=  -1;
            addChildAt(CarMC,numChildren - 1);
            MoveCar = new Tween(CarMC,"x",None.easeNone,800,-260,12,true);
            MoveCar.addEventListener(TweenEvent.MOTION_FINISH, CarFinished);
            MoveCar.start();
        }
        CarNumber++;
    }

    // Loads another car when finished
    function CarFinished(e:TweenEvent):void
    {
        removeChild(getChildByName("CarNumber_"+CarNumberR));
        CarNumberR++;
    }

这一切都很完美(好的,但这不是当前的问题)*

在这个游戏中,您还可以拾取和放置对象.使用以下代码:

    function addBuilding(Text:String)
    {
        HoldingBuilding = true;
        CursorPointer.visible = false;
        CursorGrab.visible = true;
        Building = new CarWash();
        Building.x = MouseX - MouseX % size;
        Building.y = MouseY - MouseY % size2;
        Building.rotation = 0;
        addChildAt(Building,numChildren);
    }

再次这种方法很好,当你将建筑物悬停在汽车上时,汽车停在汽车下面.(喜欢它应该)

当你将汽车放置在离道路太近的地方时会发生问题,而对于第一栋建筑来说,它可以正常工作,但如果你增加第二栋建筑,汽车将进入最新的建筑物和最古老的建筑物.

而且我无法弄清楚如何将放置的建筑物保持在顶部或将车辆保持在底部

这是放置代码:

function DropBuilding(e:MouseEvent):void
        {
            if (HoldingBuilding)
            {
                if (BuildingPlacement)
                {
                    HoldingBuilding = false;
                    BuildingPlacement = false;
                    CursorPointer.visible = true;
                    CursorGrab.visible = false;

                    Building.x = MouseX - MouseX % size;
                    Building.y = MouseY - MouseY % size2;
                    Building.rotation = 0;
                    Building.transform.colorTransform = NoColour;
                    Building.removeChild(BuildingBase);
                    BuildingBase = new Sprite();
                    BuildingShaddow = new Sprite();
                    ShakeTimer.stop();
                }
                else
                {
                    ShakeTimer.start();
                }
            }
        }

提前感谢您所做的任何事情,以帮助保持建筑物在顶部或汽车始终在底部.

礼

---

*只是因为你想知道这个问题我有汽车补间目前是每一次都没有(我还没有解决原因)一两辆汽车将停止移动5秒然后消失.

Answer 1

每次你在你的animateCars()功能中生成一辆汽车,你可以遍历所有的孩子并将建筑物放在汽车上方,但这有点乏味和不必要(而且效率不高).

这将是一个更好的方法:

//create a container for the cars
var carContainer:Sprite = new Sprite();
addChild(carContainer);

//create a container for the buildings
var buildingContainer:Sprite = new Sprite();
addChild(buildingContainer);

自从您添加buildingContainer之后carContainer,它将始终位于顶部(包括您放入其中的所有内容)

所以现在你的animateCars方法:

public function animateCars()
{
    CarMC = Random_Car();
    carContainer.addChild(CarMC);

    if (CarLeft)
    {
        CarMC.x = 0;
        CarMC.y = 245;
        MoveCar = new Tween(CarMC,"x",None.easeNone,-60,900,12,true);
    }
    else
    {
        CarMC.x = 0;
        CarMC.y = 258;
        CarMC.scaleX *=  -1;
        MoveCar = new Tween(CarMC,"x",None.easeNone,800,-260,12,true);
    }


    MoveCar.addEventListener(TweenEvent.MOTION_FINISH, CarFinished);
    MoveCar.start();
}

然后你的carFinished方法:

function CarFinished(e:TweenEvent):void
{
    carContainer.removeChild((e.currentTarget as Tween).obj as Random_Car);
}

然后在您的addBuilding方法中,更改addChildAt(Building,numChildren);为:

buildingContainer.addChild(Building);