检查字符串是否包含单词但仅在特定位置？

Question

如何检查字符串是否包含子字符串,但仅限于特定位置？

示例字符串:

你最喜欢的颜色是什么？我最喜欢的颜色是蓝色

如果我想检查字符串是否包含特定单词,我通常会这样做:

var
  S: string;
begin
  S := 'What is your favorite color? my [favorite] color is blue';
  if (Pos('favorite', S) > 0) then
  begin
    //
  end;
end;

我需要的是确定字符串中是否存在单词favourite,忽略它是否出现在[]符号中,上面的代码示例显然没有.

因此,如果我们将代码放入布尔函数中,一些示例结果将如下所示:

TRUE:你最喜欢的颜色是什么？我的[ 我最喜欢的 ]颜色是蓝色

TRUE:你最喜欢的颜色是什么？我的[ 等等 ]颜色是蓝色的

FALSE:你的等级是什么颜色？我最喜欢的颜色是蓝色

上面的前两个样本都是真的,因为在[]符号之外找到了收藏词,无论它是否在其中.

第三样是假的,因为即使是最喜欢的词,它仅出现在[]符号里面 - 如果它存在的标志外,我们应该只检查.

所以我需要一个函数来确定一个单词(在这个例子中是最喜欢的)是否出现在一个字符串中,但忽略了这个单词被包含在[]符号中的事实.

Answer 1

我喜欢Sertac's idea删除括号括起来的字符串,然后搜索字符串.以下是通过搜索整个单词和区分大小写扩展的代码示例:

function ContainsWord(const AText, AWord: string; AWholeWord: Boolean = True;
  ACaseSensitive: Boolean = False): Boolean;
var
  S: string;
  BracketEnd: Integer;
  BracketStart: Integer;
  SearchOptions: TStringSearchOptions;
begin
  S := AText;
  BracketEnd := Pos(']', S);
  BracketStart := Pos('[', S);
  while (BracketStart > 0) and (BracketEnd > 0) do
  begin
    Delete(S, BracketStart, BracketEnd - BracketStart + 1);
    BracketEnd := Pos(']', S);
    BracketStart := Pos('[', S);
  end;
  SearchOptions := [soDown];
  if AWholeWord then
    Include(SearchOptions, soWholeWord);
  if ACaseSensitive then
    Include(SearchOptions, soMatchCase);
  Result := Assigned(SearchBuf(PChar(S), StrLen(PChar(S)), 0, 0, AWord,
    SearchOptions));
end;

这是函数的优化版本,它使用指针字符迭代而不进行字符串操作.与之前的版本相比,当你有一个缺少右括号的字符串时就会处理这种情况My [favorite color is.由于缺少括号,这样的字符串被评估为True.

原则是通过char遍历整个字符串char,当你找到开括号时,查看该括号是否有自己的结束对.如果是,则检查存储位置的子字符串是否包含搜索的单词.如果是,请退出该功能.如果不是,请将存储的位置移动到右括号.如果左括号没有自己的闭合对,则从存储位置搜索单词到整个字符串的末尾并退出该函数.

对于此代码的评论版本,请点击此链接.

function ContainsWord(const AText, AWord: string; AWholeWord: Boolean = True;
  ACaseSensitive: Boolean = False): Boolean;
var
  CurrChr: PChar;
  TokenChr: PChar;
  TokenLen: Integer;
  SubstrChr: PChar;
  SubstrLen: Integer;
  SearchOptions: TStringSearchOptions;
begin
  Result := False;
  if (Length(AText) = 0) or (Length(AWord) = 0) then
    Exit;
  SearchOptions := [soDown];
  if AWholeWord then
    Include(SearchOptions, soWholeWord);
  if ACaseSensitive then
    Include(SearchOptions, soMatchCase);
  CurrChr := PChar(AText);
  SubstrChr := CurrChr;
  SubstrLen := 0;
  while CurrChr^ <> #0 do
  begin
    if CurrChr^ = '[' then
    begin
      TokenChr := CurrChr;
      TokenLen := 0;
      while (TokenChr^ <> #0) and (TokenChr^ <> ']') do
      begin
        Inc(TokenChr);
        Inc(TokenLen);
      end;
      if TokenChr^ = #0 then
        SubstrLen := SubstrLen + TokenLen;
      Result := Assigned(SearchBuf(SubstrChr, SubstrLen, 0, 0, AWord,
        SearchOptions));
      if Result or (TokenChr^ = #0) then
        Exit;
      CurrChr := TokenChr;
      SubstrChr := CurrChr;
      SubstrLen := 0;
    end
    else
    begin
      Inc(CurrChr);
      Inc(SubstrLen);
    end;
  end;
  Result := Assigned(SearchBuf(SubstrChr, SubstrLen, 0, 0, AWord,
    SearchOptions));
end;

Answer 2

在正则表达式中,有一种可以使用的称为环视的东西.在你的情况下,你可以用负面的lookbehind解决它:你想要"最喜欢的",除非它之前有一个开放括号.它可能看起来像这样:

(?<!\[[^\[\]]*)favorite

一步一步:(?<!是负面的lookbehind前缀,我们正在寻找\[可选地后跟没有或者更多没有关闭或打开括号的东西:[^\[\]]*,关闭负面的lookbehind ),然后紧接着favorite.