as3使用airxzip压缩和解压缩文件

Question

我想使用airxzip,但我不知道如何下载源文件以及如果我这样做的话放在哪里.

我很抱歉成为这样的新手.

谢谢你尽你所能的帮助.

下面是我试图访问的zip/unzip as3代码的链接.

http://flex.coltware.com/2010/05/01/as3-zip-unzip-lib-airxzip/

下面是"解压缩"的示例,但我不知道如何下载要导入的文件.

// ActionScript file
import com.coltware.airxzip.ZipEntry;
import com.coltware.airxzip.ZipError;
import com.coltware.airxzip.ZipFileReader;
import com.coltware.airxzip.*;

import flash.filesystem.File;
import flash.utils.ByteArray;

use namespace zip_internal;

public function unzip_init(filename:String):ZipFileReader{
        var reader:ZipFileReader = new ZipFileReader();
        var file:File = File.desktopDirectory.resolvePath(filename);
        reader.open(file);
        return reader;
}

public function unzip_sample1():void{
        var reader:ZipFileReader = unzip_init("new_airxzip.zip");
        var list:Array = reader.getEntries();

        for each(var entry:ZipEntry in list){

                if(entry.isDirectory()){
                        log.debug("DIR  --->" + entry.getFilename());
                }
                else{
                        log.debug("FILE --->" + entry.getFilename() + "(" + entry.getCompressRate() + ")");
                }
        }
}

public function unzip_sample2():void{
        var reader:ZipFileReader = unzip_init("new_airxzip.zip");
        var list:Array = reader.getEntries();

        for each(var entry:ZipEntry in list){
                if(!entry.isDirectory()){
                        if(entry.getFilename() == "sample.txt"){
                                var bytes:ByteArray = reader.unzip(entry);
                                log.debug("sample.txt : " + bytes);
                        }
                }
        }
}

public function unzip_sample3():void{
        var reader:ZipFileReader = unzip_init("crypto_airxzip.zip");
        reader.setPassword("pass");
        var list:Array = reader.getEntries();

        for each(var entry:ZipEntry in list){
                if(!entry.isDirectory()){
                        if(entry.getFilename() == "sample.txt"){
                                try{
                                        var bytes:ByteArray = reader.unzip(entry);
                                        log.debug("sample.txt : " + bytes);
                                }
                                catch(e:ZipError){
                                        log.warn(entry.getFilename() + ":" + e.message);
                                }
                        }
                }
        }
}
public function unzip_sample4():void{
        var reader:ZipFileReader = unzip_init("abc.zip");
        var list:Array = reader.getEntries();
        for each(var entry:ZipEntry in list){
                entry.dumpLogInfo();
        }
}

Answer 1

Flash Builder

1. Download the SWC File. airxzip

2. In your flash builder project make a库folder. and downloaded SWC files drag and drop or copy.

3. In your project mouse right click and Properties click.

4. Actionscript Build Path - Library Path - Add SWC Folder click and input a libs

Flash (below image Mac OS)

1. File-ActionScript Settings Click

2. Browse to SWC File icon Click. and downloaded your SWC File link.

3. publish setting, Target set a AIR2.5 or AIR 3.X ios or AIR 3.X Android.

4. check out below my sample code. I tested. 这是一个示例代码.simple_unzip

import com.coltware.airxzip.ZipEntry;
import com.coltware.airxzip.ZipError;
import com.coltware.airxzip.ZipFileReader;
import com.coltware.airxzip.*;

import flash.filesystem.File;
import flash.utils.ByteArray;
import flash.net.FileReference;
import flash.net.FileFilter;

var file:File;
var fileReference:FileReference;
var fileFilter:FileFilter;

function unzip_init():void{

    fileFilter = new FileFilter("selected your zip file.", "*.zip; .gz2; .bz2;");
    file = new File();
    file.browseForOpen("\Users", [fileFilter]);
    file.addEventListener(Event.SELECT, onSelectedFile);
}

function onSelectedFile(e:Event):void
{
    var reader:ZipFileReader = new ZipFileReader();
    reader.open(file);

    var list:Array = reader.getEntries();

        for each(var entry:ZipEntry in list){

                if(entry.isDirectory()){
                        trace("DIR  --->" + entry.getFilename());
                }
                else{
                        trace("FILE --->" + entry.getFilename() + "(" + entry.getCompressRate() + ")");
                }
        }
}

unzip_init();

从现在开始,可以查看示例代码.默认环境已完成.

What's the SWC?

Adobe SWC文件是一组预编译的Flash符号和ActionScript代码,允许Flash或Flex开发人员分发类和资产,或避免重新编译不会更改的符号和代码.