我在函数的最后递归调用中得到了"scheme application not a procedure"

Question

所以这是代码:

(define (time-prime-test n)
  (newline)
  (display n)
  (start-prime-test n (runtime)))

(define (start-prime-test n start-time)
  (if (prime? n)
      (report-prime (- (runtime) start-time))))

(define (report-prime elapsed-time)
  (display " *** ")
  (display elapsed-time))

(define (search-for-primes n m)
  (if (< n m) 
      ((time-prime-test n)
       (search-for-primes (+ n 1) m))
      (display " calculating stopped. ")))
(search-for-primes 100000 100020)

我在"计算停止"后得到了这个错误.已经显示.如下:

100017 100018 100019 * 54计算停止...申请:不是程序; 期望一个可以应用于给
定参数的过程:#<void>
arguments ...:
#<void>

Answer 1

您打算在后续部分中执行两个表达式if,但if只允许在结果中使用一个表达式,在备选中使用一个表达式.

围绕括号之间的两个表达式(如您所做)将不起作用:结果表达式将被计算为第一个表达式的函数应用程序,第二个表达式作为其参数,产生错误"application: not a procedure; expected a procedure that can be applied to arguments ...",因为(time-prime-test n)不计算过程,它评估为#<void>.

您可以使用以下方法解决问题cond:

(define (search-for-primes n m)
  (cond ((< n m)
         (time-prime-test n)
         (search-for-primes (+ n 1) m))
        (else
         (display " calculating stopped. "))))

或者begin:

(define (search-for-primes n m)
  (if (< n m)
      (begin
        (time-prime-test n)
        (search-for-primes (+ n 1) m))
      (display " calculating stopped. ")))