Clojure core.logic 中的因子

Question

我想使用 core.logic 编写阶乘。我找到了这个序言片段

factorial(0, 1).
factorial(N, M):- N1 is N - 1, factorial (N1, M1), M is N*M1.

并尝试通过以下方式将其转换为 core.logic

(defne factorialo [n m]
  ([0 1])
  ([n m] (fresh [n1 m1]
            (== (- n 1) n1)
            (== (* n m1) m)
            (factorialo n1 m1))))

(run* [q]
  (factorialo 3 q))

消息失败

clojure.core.logic.LVar cannot be cast to java.lang.Number
  [Thrown class java.lang.ClassCastException]

在 core.logic 中编写阶乘的正确方法是什么？

Answer 1

Prolog 中的算术通常意味着隐式投影 - 您不再与逻辑变量相关地工作，而是使用它们绑定的实际值。在 core.logic 中还没有好用的糖，您必须明确投影：

(defne factorialo [n m]
  ([0 1])
  ([n m]
     (fresh [n1 m1]
       (project [n]
         (== n1 (- n 1)))
       (factorialo n1 m1)
       (project [n m1]
         (== m (* n m1))))))

(run 1 [q]
  (factorialo 3 q))

在 core.logic 0.8.0 alphas 中，支持有限域上的约束逻辑编程。这改进了 Prolog 的算术故事：

(defne factorialfd [n m]
  ([0 1])
  ([n m]
     (fresh [n1 m1]
       (infd n1 m1 (interval 0 Integer/MAX_VALUE))
       (+fd n1 1 n)
       (factorialfd n1 m1)
       (*fd n m1 m))))

(run 1 [q]
  (infd q (interval 0 Integer/MAX_VALUE))
  (factorialfd 3 q))

请注意，变量的域必须明确，但我们不再需要为投影而烦恼。然而，这项工作是非常 alpha 状态，这个解决方案在未来的样子可能会发生变化。