HLSL无效ps_2_0输入语义POSITION0

Question

我正在尝试在RenderMonkey中为Dx9编写一个phong着色器效果.

我在像素着色器中遇到编译错误

*"无效的ps_2_0输入语义'POSITION0'"*

我不知道如何修复它,虽然我知道它必须与VS_OUTPUT中的POSITION0语义有关.

我尝试将VS_OUTPUT的Pos语义更改为TEXCOORD0,但系统会报告

顶点着色器必须最低限度地写入POSITION的所有四个组件

着色器在下面提供.有什么建议？

这是我的顶点着色器:

struct VS_INPUT 
{
   float4 Pos : POSITION0;
   float3 Normal : NORMAL0;
};

struct VS_OUTPUT 
{
   float4 Pos : POSITION0;
   float3 Normal : TEXCOORD0;
};

VS_OUTPUT vs_main( VS_INPUT Input )
{
   VS_OUTPUT Output;

   Output.Pos     = Input.Pos;
   Output.Normal  = Input.Normal;

   return Output;  
}

和我的像素着色器:

    float4x4 matViewProjection;

// light source
float4 lightPos;
float4 Ambient;
float4 Diffuse;
float4 Specular;

// material reflection properties
float4 Ke;
float4 Ka;
float4 Kd;
float4 Ks;
float  nSpecular;

// eye
float4 eyePosition;

struct VS_OUTPUT 
{
   float4 Pos : POSITION0;
   float3 Normal : TEXCOORD0;
};

float4 ps_main( VS_OUTPUT vsOutput ) : COLOR0
{   
   vsOutput.Pos = mul( vsOutput.Pos, matViewProjection );


   float3 ViewDirection = normalize( eyePosition.xyz - vsOutput.Pos.xyz );
   float3 LightDirection = normalize( lightPos.xyz - vsOutput.Pos.xyz );

   float3 N = normalize( vsOutput.Normal );
   float3 R = reflect( -LightDirection, N );

   float LdotN = max( 0.0, dot( LightDirection, N ) );
   float VdotR = max( 0.0, dot( ViewDirection, R ) );

   // find colour components
   float4 a = Ka * Ambient;
   float4 d = Kd * Diffuse * LdotN;
   float4 s = Ks * Specular * pow( VdotR, nSpecular );

   float4 FragColour = Ke + a + d + s;
   return FragColour;
}

Answer 1

好的,我为那些感兴趣的人找到了解决方案.

顶点着色器应定义以下结构:

struct VS_INPUT 
{
   float4 Pos : POSITION0;
   float3 Normal : NORMAL0;
};

struct VS_OUTPUT 
{
   float4 Pos : POSITION0;
   float4 PosOut : TEXCOORD0;
   float3 Normal : TEXCOORD1;
};

VS_OUTPUT结构在像素着色器中应该是不同的:

struct VS_OUTPUT 
{
   float4 PosOut : TEXCOORD0;
   float3 Normal : TEXCOORD1;
};

我的问题源于你不能将POSITION语义作为像素着色器的输入.至少对于ps_2_0.