带类的Clojure案例陈述

Question

我想打开给定对象的类以对其进行编码.

(defn encoded-msg-for [msg]
  (case (class msg)
    java.lang.Double   (encode-double msg)
    java.lang.String   (encode-str msg)
    java.lang.Long   (encode-int msg)
    java.lang.Boolean  (encode-bool msg)
    clojure.lang.PersistentArrayMap (encode-hash msg)
    clojure.lang.PersistentVector (encode-vec msg)
    nil "~"
  )
 )

当我打电话时(encoded-msg-for {}),它会返回No matching clause: class clojure.lang.PersistentArrayMap

奇怪的是,将案例放入哈希映射(将类作为键和字符串作为值)非常有效.

也是的,(= (class {}) clojure.lang.PersistentArrayMap)是的.在这里进行了什么比较,我如何切换对象本身的类或(更好)在其层次结构中的某些东西？

Answer 1

我相信case将类名称视为文字符号 - 它不会将它们解析为实际的类:

>>> (case 'clojure.lang.PersistentArrayMap clojure.lang.PersistentArrayMap 1 17)
1

>>> (case clojure.lang.PersistentArrayMap clojure.lang.PersistentArrayMap 1 17)
17

这是相当不直观的,但它适用于Clojure case.无论如何,惯用的方式是使用defmulti而defmethod不是开启type:

(defmulti encoded-msg class)

(defmethod encoded-msg java.util.Map [x] 5)

(defmethod encoded-msg java.lang.Double [x] 7)

>>> (encoded-msg {})
5

>>> (encoded-msg 2.0)
7

调度程序使用isa?谓词,该谓词处理类型的比较,特别是它适用于Java继承.

如果您不想使用defmulti,那么condp可能会case在您的用例中替换,因为它正确评估了测试表达式.另一方面,它不提供恒定的时间分派.

Answer 2

如果您只在类上调度,那么协议可能是一个很好的解决方案,因为它们将使您(或您的API的客户端)能够在以后为其他类型提供实现,这是一个示例:

(defprotocol Encodable
  (encode [this]))

(extend-protocol Encodable
  java.lang.String
  (encode [this] (println "encoding string"))
  clojure.lang.PersistentVector
  (encode [this] (println "encoding vector")))

如果您需要进行更细粒度的调度,或者您知道不需要扩展到其他类型,那么此解决方案中可能存在太多样板.