无法使用XSLT变量来保存属性

Question

在我的xslt模板中,我有一个for-each声明.因为for-each我在做不同的条件.我希望有一个字符串类型的变量,它应包含将分配给a的类属性<li>.

由于我是xslt的新手,请提供一些示例或如何实现我想要做的事情.

这是我的一些代码,所以你可以看到我正在采取的措施:

<xsl:if test="count($currentPage/ancestor-or-self::* [@level=$level]/* [@isDoc and string(umbracoNaviHide) != '1']) &gt; '0'">
    <xsl:for-each select="$currentPage/ancestor-or-self::* [@level=$level]/* [@isDoc and string(umbracoNaviHide) != '1']">
        <li><xsl:attribute name="class">
                topNavigLi
                page<xsl:number value="position()" format="1" />
                <xsl:if test="@nodeName='Network' ">
                    has_submenu network
                </xsl:if>
            </xsl:attribute>
            <xsl:if test="@id = $currentPage/@id">
                <xsl:attribute name="class">
                    current topNavigLi
                    page<xsl:number value="position()" format="1" />
                </xsl:attribute>
            </xsl:if>
            <xsl:if test="position() = last()">
                <xsl:attribute name="class">
                    last topNavigLi
                    page<xsl:number value="position()" format="1" />
                </xsl:attribute>
            </xsl:if>

            <xsl:if test="@id = $currentPage/@id and position() = last()">
                <xsl:attribute name="class">
                    current last topNavigLi
                    page<xsl:number value="position()" format="1" />
                </xsl:attribute>
            </xsl:if>

在进行测试时,有一个变量而不是连接它会更加优雅.我试过这样但没有回报.

<xsl:variable name="li_class" select="page"> </xsl:variable>

<xsl:attribute name="class">
    <xsl:value-of select="li_class" /> 
</xsl:attribute>

Answer 1

这是一个我认为你要求的例子:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="/*">
     <xsl:copy>
       <xsl:apply-templates/>
     </xsl:copy>
 </xsl:template>

 <xsl:template match="num">
  <xsl:variable name="vResult">

    <xsl:if test=". mod 2 = 0">Even </xsl:if>
    <xsl:if test=". mod 3 = 0"> mult3</xsl:if>
    <xsl:if test="not(. mod 2 = 0 or . mod 3 = 0)">none</xsl:if>
  </xsl:variable>

  <xsl:variable name="vnormResults" select="normalize-space($vResult)"/>

  <num tests="{$vnormResults}">
   <xsl:value-of select="."/>
  </num>
 </xsl:template>
</xsl:stylesheet>

将此转换应用于以下XML文档时:

<nums>
  <num>01</num>
  <num>02</num>
  <num>03</num>
  <num>04</num>
  <num>05</num>
  <num>06</num>
  <num>07</num>
  <num>08</num>
  <num>09</num>
  <num>10</num>
</nums>

结果是:

<nums>
   <num tests="none">01</num>
   <num tests="Even">02</num>
   <num tests="mult3">03</num>
   <num tests="Even">04</num>
   <num tests="none">05</num>
   <num tests="Even mult3">06</num>
   <num tests="none">07</num>
   <num tests="Even">08</num>
   <num tests="mult3">09</num>
   <num tests="Even">10</num>
</nums>