还原备份时,如何断开所有活动连接？

Question

由于活动连接,我的SQL Server 2005无法还原备份.我怎么强迫它？

Answer 1

您希望将数据库设置为单用户模式,执行还原,然后将其设置回多用户:

ALTER DATABASE YourDB
SET SINGLE_USER WITH
ROLLBACK AFTER 60 --this will give your current connections 60 seconds to complete

--Do Actual Restore
RESTORE DATABASE YourDB
FROM DISK = 'D:\BackUp\YourBaackUpFile.bak'
WITH MOVE 'YourMDFLogicalName' TO 'D:\Data\YourMDFFile.mdf',
MOVE 'YourLDFLogicalName' TO 'D:\Data\YourLDFFile.ldf'

/*If there is no error in statement before database will be in multiuser
mode.  If error occurs please execute following command it will convert
database in multi user.*/
ALTER DATABASE YourDB SET MULTI_USER
GO

参考:Pinal Dave(http://blog.SQLAuthority.com)

官方参考:https://msdn.microsoft.com/en-us/library/ms345598.aspx

Answer 2

SQL Server Management Studio 2005

右键单击数据库并单击Tasks然后单击时Detach Database,将显示一个包含活动连接的对话框.

分离屏幕http://www.kodyaz.com/images/articles/kill-all-processes/detach-database.JPG

通过单击"消息"下的超链接,您可以终止活动连接.

然后,您可以在不分离数据库的情况下终止这些连接.

更多信息在这里.

SQL Server Management Studio 2008

SQL Server Management Studio 2008的界面已更改,以下是步骤(通过:Tim Leung)

1. 在对象资源管理器中右键单击服务器,然后选择"活动监视器".
2. 打开时,展开"进程"组.
3. 现在使用下拉列表按数据库名称过滤结果.
4. 通过选择右键单击"Kill Process"选项来终止服务器连接.

Answer 3

这段代码对我有用,它会杀死数据库的所有现有连接.您所要做的就是更改行@dbname ='databaseName',以便它具有您的数据库名称.

Use Master
Go

Declare @dbname sysname

Set @dbname = 'databaseName'

Declare @spid int
Select @spid = min(spid) from master.dbo.sysprocesses
where dbid = db_id(@dbname)
While @spid Is Not Null
Begin
        Execute ('Kill ' + @spid)
        Select @spid = min(spid) from master.dbo.sysprocesses
        where dbid = db_id(@dbname) and spid > @spid
End

在此之后,我能够恢复它

Answer 4

重新启动SQL Server将断开用户连接.我找到的最简单的方法 - 如果您想让服务器脱机也很好.

但是出于一些非常奇怪的原因,"Take Offline"选项不能可靠地执行此操作,并且可能会挂起或混淆管理控制台.重新启动然后离线工作

有时这是一个选项 - 例如,如果你已经停止了作为连接源的网络服务器.

Answer 5

尝试这个：

DECLARE UserCursor CURSOR LOCAL FAST_FORWARD FOR
SELECT
    spid
FROM
    master.dbo.sysprocesses
WHERE DB_NAME(dbid) = 'dbname'--replace the dbname with your database
DECLARE @spid SMALLINT
DECLARE @SQLCommand VARCHAR(300)
OPEN UserCursor
FETCH NEXT FROM UserCursor INTO
    @spid
WHILE @@FETCH_STATUS = 0
BEGIN
    SET @SQLCommand = 'KILL ' + CAST(@spid AS VARCHAR)
    EXECUTE(@SQLCommand)
    FETCH NEXT FROM UserCursor INTO
        @spid
END
CLOSE UserCursor
DEALLOCATE UserCursor
GO