如何使用批处理文件或脚本从一个Gmail帐户向另一个Gmail帐户发送电子邮件？

Question

我需要一个小的Windows脚本来向Gmail帐户发送一行电子邮件.我已经尝试了许多声称可以执行此操作的实用程序,例如BLAT,但都没有用.如果满足某些条件,脚本将在批处理文件中执行.脚本可以是Perl,Python,VBScript,Java,只要它从批处理文件执行就没关系.如果您通过Gmail,Hotmail或Yahoo电子邮件帐户向Gmail帐户发送电子邮件,请回答您是否尝试过您的解决方案.我默认使用的帐户是Gmail,因此我从Gmail帐户发送到Gmail帐户.

Answer 1

Blat允许您直接从批处理文件发送电子邮件:

blat.exe - -f from@example.com -to to@gmail.com -s Subject -body "Text body" ^
  -server smtp.example.com:25 -u username -pw password

但似乎Blat不支持SSL,因此要使其与Gmail一起使用,您需要一个名为Stunnel的附加工具(请参阅此处和此处).

无论如何,您应该能够使用协作数据对象(CDO) COM API 从VBScript通过GMail发送电子邮件:

Const schema   = "http://schemas.microsoft.com/cdo/configuration/"
Const cdoBasic = 1
Const cdoSendUsingPort = 2
Dim oMsg, oConf

' E-mail properties
Set oMsg      = CreateObject("CDO.Message")
oMsg.From     = "from@gmail.com"  ' or "Sender Name <from@gmail.com>"
oMsg.To       = "to@gmail.com"    ' or "Recipient Name <to@gmail.com>"
oMsg.Subject  = "Subject"
oMsg.TextBody = "Text body"

' GMail SMTP server configuration and authentication info
Set oConf = oMsg.Configuration
oConf.Fields(schema & "smtpserver")       = "smtp.gmail.com"
oConf.Fields(schema & "smtpserverport")   = 465
oConf.Fields(schema & "sendusing")        = cdoSendUsingPort
oConf.Fields(schema & "smtpauthenticate") = cdoBasic
oConf.Fields(schema & "smtpusessl")       = True
oConf.Fields(schema & "sendusername")     = "from@gmail.com"
oConf.Fields(schema & "sendpassword")     = "sender_password"
oConf.Fields.Update

oMsg.Send

编辑:添加缺少的sendusing参数,所以它现在应该工作正常.

有关更多CDO示例,请参见此处.

Answer 2

在perlmonks上查看此脚本,其中详细说明了GMail帐户上的IMAP访问权限.该帖子涵盖了通过Perl登录GMail帐户所需的一切.

或者,您可以在CPAN中尝试Mail :: Webmail :: Gmail模块.从它的外观来看,该模块可以让你跳过大部分有关连接和验证邮件服务器的复杂细节,让你有一些简单的事情 -

my $gmail = Mail::Webmail::Gmail->new( username => 'username', password => 'password', );
$gmail->send_message( to => 'user@domain.com', subject => 'Test Message', msgbody => 'This is a test.' );

如果您需要"仅"从Gmail帐户发送电子邮件,还有Email :: Send :: Gmail.