使用Parse :: RecDescent解析带有嵌套括号的字符串

Question

我正在尝试使用Parse::RecDescentmake解析器来解析括号表达式和一元运算符?.

到目前为止,我创建解析器时失败了,因为规则expression是左递归的:

use strict;
use warnings;
use Parse::RecDescent;

my $test = <<END;
((foo)? bar)
END

my $grammar = q(
    parse: expression(s)
    expression: string | parend | expression(s)
    parend : "(" (string | expression) ")" /\??/
    string : /\w+/ /\??/

);
my $parser = Parse::RecDescent->new($grammar);
my $result = $parser->parse($test);
if($result){
    print $result;
}else{
    print STDERR "Invalid grammar\n";
}

Answer 1

首先,您从最低优先级到最高优先级.

parse  : expr /\Z/

expr   : list

list   : unary(s?)

unary  : unary '?'
       | term

term   : '(' expr ')'
       | STRING

STRING : /\w+/

当然,

unary  : unary '?'
       | term

不起作用,因为它是左递归的.Parse :: RecDescent中的运算符关联和消除左递归可以帮助您摆脱它.我们得到了

unary  : term unary_(s?)
unary_ : '?'

但是,这不会为我们构建正确的树.所以让我们从平局" (s?)"开始吧.

unary  : term unary_
unary_ : '?' unary_
       |

然后我们可以使用subrule args创建正确的树.

unary  : term unary_[ $item[1] ]
unary_ : '?' unary_[ [ 'postfix?' => $arg[0] ] ]
       | { $arg[0] }

全部一起:

use strict;
use warnings;
use Data::Dumper      qw( Dumper );
use Parse::RecDescent qw( );

my $grammar = <<'END';
   {
      use strict;
      use warnings;
   }

   parse  : expr /\Z/ { $item[1] }

   expr   : list

   list   : unary(s?) { [ $item[0] => @{ $item[1] } ] }

   unary  : term unary_[ $item[1] ]
   unary_ : '?' unary_[ [ 'postfix?' => $arg[0] ] ]
          | { $arg[0] }

   term   : '(' expr ')' { $item[2] }
          | STRING { [ string => $item[1] ] }

   STRING : /\w+/

END

my $parser = Parse::RecDescent->new($grammar)
   or die "Invalid grammar\n";
my $tree = $parser->parse("((foo bar)? baz)\n")
   or die "Invalid text\n";
print(Dumper($tree));