使用 DBIx::Class 的多对多对多访问器

Question

使用 DBIx::Class，我尝试创建一个跨越两个链接表的多对多访问器（甚至只是一个多对关系）。

所讨论的三个数据表是Users、Roles和Pages，以及两个链接表UserRoles和RolePages。这些表是相关的：

• 一个用户有多个用户角色
• 一个角色有多个UserRoles
• 一个角色有多个角色页面
• 一个Page有很多RolePage

Catalyst 帮助程序脚本为我创建了这些关系和访问器：

package MyApp::Schema::Result::User;

__PACKAGE__->has_many(
  "user_roles",
  "MyApp::Schema::Result::UserRole",
  { "foreign.username" => "self.username" },
  { cascade_copy => 0, cascade_delete => 0 },
);

__PACKAGE__->many_to_many("roles", "user_roles", "role");


package MyApp::Schema::Result::Role;

__PACKAGE__->has_many(
  "role_pages",
  "MyApp::Schema::Result::RolePage",
  { "foreign.role" => "self.role" },
  { cascade_copy => 0, cascade_delete => 0 },
);

__PACKAGE__->has_many(
  "user_roles",
  "MyApp::Schema::Result::UserRole",
  { "foreign.role" => "self.role" },
  { cascade_copy => 0, cascade_delete => 0 },
);

__PACKAGE__->many_to_many("page_names", "role_pages", "page_name")

__PACKAGE__->many_to_many("usernames", "user_roles", "username");


package MyApp::Schema::Result::Page;

__PACKAGE__->has_many(
  "role_pages",
  "MyApp::Schema::Result::RolePage",
  { "foreign.page_name" => "self.page_name" },
  { cascade_copy => 0, cascade_delete => 0 },
);

__PACKAGE__->many_to_many("roles", "role_pages", "role");


package MyApp::Schema::Result::UserRole;

__PACKAGE__->belongs_to(
  "role",
  "MyApp::Schema::Result::Role",
  { role => "role" },
  { is_deferrable => 1, on_delete => "CASCADE", on_update => "CASCADE" },
);

__PACKAGE__->belongs_to(
  "username",
  "MyApp::Schema::Result::User",
  { username => "username" },
  { is_deferrable => 1, on_delete => "CASCADE", on_update => "CASCADE" },
);


package MyApp::Schema::Result::RolePage;

__PACKAGE__->belongs_to(
  "page_name",
  "MyApp::Schema::Result::Page",
  { page_name => "page_name" },
  { is_deferrable => 1, on_delete => "CASCADE", on_update => "CASCADE" },
);

__PACKAGE__->belongs_to(
  "role",
  "MyApp::Schema::Result::Role",
  { role => "role" },
  { is_deferrable => 1, on_delete => "CASCADE", on_update => "CASCADE" },
);

我的最终目标是有一种干净的方法来获取应为当前用户显示的页面列表。IE：

foreach my $page ($c->user->pages) {
    # do something with $page
}

我在 MyApp::Schema::Result::User 类中确实有这个方法：

sub pages {
    my ($self) = @_;

    return $self->result_source->schema->resultset('RolePage')->search(
        {
            'username.username' => $self->username,
        },
        {
            join => [
                {
                    role => {user_roles => 'username'},
                },
                'page_name',
            ],
        }
    );
}

直到我添加一个类来扩展 MyApp::Schema::Result::RolePage 为止，该方法一直有效。该课程是这样开始的：

package MyApp::Schema::ResultSet::RolePage;

use Moose;
use namespace::autoclean;
extends qw/MyApp::Schema::ResultSetX::DisplayTable/;

has '+name' => ( default => 'RolePage' );

我在我的应用程序中使用了这种技术来创建各种结果集，但现在才遇到了麻烦。我收到此错误：

在 Lifeway::Controller::Root->auto 中捕获异常“new() 的单个参数必须是 HASH 引用

这是我的方法造成的MyApp::Schema::Result::User->pages()。因此，为了避免此错误，我想尝试创建从Users到Pages的多对多访问器（甚至只是一个多对关系）。

是否可以创建这样一个跨越两个链接表的访问器/关系？如果是这样，怎么办？我在文档中找不到示例，并且自己也没有想法。如果做不到这一点，有什么想法可以解释为什么我的pages()方法会出现这个错误吗？

Answer 1

据我所知，没有对多对多对多关系的内置支持，但推出自己的关系并不太难。

在架构::结果::User.pm 中

sub pages {
  my $self = shift;
  return $self->search_related('user_roles')
    ->search_related('role')
    ->search_related('role_pages')
    ->search_related('page_name');
    # Alternatively, if you need to eliminate duplicates:
    # ->search_related('page_name', {}, {distinct => 1});
}

我认为，这与标准 DBIx 多对多关系桥的功能相当接近。