Spreadsheet :: WriteExcel基于其他单元格值的条件格式

Question

我正在尝试在Excel工作表中添加条件格式.不幸的是,Spreadsheet :: WriteExcel页面上的示例太简单了,我不知道该怎么做.

我想通过RC10单元格值更改行背景颜色.在excel中,我将添加格式化公式

=IF(RC10="xxxx";1;0)

我试过在Spreadsheet :: WriteExcel中做类似的事情:

my $detail_rest_fmt = $excel->add_format(font => "Calibri", size => 11, valign  => "vcenter", align => "right", border => 1);
$detail_rest_fmt->set_num_format("[Green]=IF(RC10=\"xxxx\";1;0);[Red]=IF(RC10=\"yyyyyy\";1;0)"); 

但没有任何影响.

Answer 1

坏消息是我认为这很难用 Spreadsheet::WriteExcel 来完成。

好消息是可以使用 Excel::Writer::XLSX 轻松完成。它恰好是 Spreadsheet::WriteExcel 的一种后代。请阅读文章： Spreadsheet::WriteExcel 已死。Excel::Writer::XLSX 万岁

以下代码完全执行您想要的格式设置（仅基于单元格 A1 而不是 RC10，当然可以更改）：

#!/usr/bin/perl -w
use strict;
use Excel::Writer::XLSX;

my @matrix = (
    ['xxxx', '<-- Change the value in cell A1 to change the colour of row 4'],
    [qw(Redyard Kipling)],
    [qw(If--)],
    [qw(If you can keep your head when all about you)],
    [qw(Are losing theirs and blaming it on you;)],
);

writeSpreadsheet('conditional.formatting.xlsx', \@matrix);

sub writeSpreadsheet {
    my ($outFile, $matrix) = @_;
    my $MIN_COL_WIDTH = 5;
    my $MAX_COL_WIDTH = 35;
    my $workbook = Excel::Writer::XLSX->new($outFile);
    my $worksheet = $workbook->add_worksheet();
    my $redFormat = $workbook->add_format(font => 'Arial', color => 'red');
    my $greenFormat = $workbook->add_format(font => 'Arial', color => 'green', bold => 1);
    $worksheet->set_row(0, undef,
        $workbook->add_format(font => 'Arial', align => 'center', bold => 1));
    $worksheet->conditional_formatting('A4:Z4',
        {
            type => 'formula',
            criteria => '=$A$1 = "xxxx"',
            format => $greenFormat
        }
    );
    $worksheet->conditional_formatting('A4:Z4',
        {
            type => 'formula',
            criteria => '=$A$1 = "yyyyyy"',
            format => $redFormat
        }
    );
    foreach my $row (0 .. $#$matrix) {
        foreach my $col (0 .. $#{$matrix->[$row]}) {
            $worksheet->write($row, $col, $matrix->[$row][$col] || '');
        }
    }
}