使用常规程序处理类事件(Delphi)

Question

我在一个简单的过程(不是类中的方法)内以编程方式创建数据库连接对象.

mydb:= TUniConnection.Create(nil);
mydb.Database:= knowledge_db_name;
mydb.LoginPrompt:= False;
mydb.Username:= aaa;
mydb.Password:= bbb;

现在我需要处理错误和与其他程序断开连接.当我尝试做的时候:

mydb.OnError:= OnConnectionError;
mydb.OnConnectionLost:= OnConnectionLost;

编译告诉我

[DCC Error] test.pas(373): E2009 Incompatible types: 'method pointer and regular procedure'

我该如何解决这个问题？以下是事件过程的定义:

procedure OnConnectionError(Sender: TObject; E: EDAError; var Fail: Boolean);
procedure OnConnectionLost(Sender: TObject; Component: TComponent; ConnLostCause: TConnLostCause; var RetryMode: TRetryMode);

Answer 1

如果您没有合适的类来放置事件处理程序,则可以定义一个虚拟类并生成事件处理程序class procedure.然后,您不必创建类的实例,但可以分配mydb.OnError:= TMyDummyEventHandlerClass.OnConnectionError;.

这是一个例子 - 我使用不同的事件,因为我没有,TUniConnection但想确保一切都编译.:-)

type
  // Dummy class to hold event handlers:
  TXMLEventHandlers = class
    // Event handlers:
    class procedure OnBeforeOpen(Sender: TObject);
    class procedure OnAfterOpen(Sender: TObject);
  end;

class procedure TXMLEventHandlers.OnBeforeOpen(Sender: TObject);
begin
  MessageBox(0, PChar(ClassName + '.OnBeforeOpen'), nil, 0)
end;

class procedure TXMLEventHandlers.OnAfterOpen(Sender: TObject);
begin
  MessageBox(0, PChar(ClassName + '.OnAfterOpen'), nil, 0)
end;

procedure Test;
var
  xml: TXMLDocument;
begin
  xml := TXMLDocument.Create(nil);
  try
    // Note: No instance of `TXMLEventHandlers` must be created:
    xml.AfterOpen := TXMLEventHandlers.OnAfterOpen;
    xml.BeforeOpen := TXMLEventHandlers.OnBeforeOpen;

    xml.Active := True; // Calls the two event handlers
  finally
    xml.Free;
  end;
end;