perl中的双花括号

Question

我在线查看perl代码并遇到了一些我以前从未见过的东西,但却无法知道它在做什么(如果有的话).

if($var) {{
   ...
}}

有谁知道双花括号是什么意思？

Answer 1

那里有两个陈述."if"语句和裸块.裸块是仅执行一次的循环.

say "a";
{
   say "b";
}
say "c";

# Outputs a b c

但作为循环,它们确实会影响next,last并且redo.

my $i = 0;
say "a";
LOOP: {  # Purely descriptive (and thus optional) label.
   ++$i;
   say "b";
   redo if $i == 1;
   say "c";
   last if $i == 2;
   say "d";
}
say "e";

# Outputs a b b c e

(next与last没有下一个元素的情况相同.)

它们通常用于创建词法范围.

my $file;
{
   local $/;
   open(my $fh, '<', $qfn) or die;
   $file = <$fh>;
}
# At this point,
# - $fh is cleared,
# - $fh is no longer visible,
# - the file handle is closed, and
# - $/ is restored.

目前还不清楚为什么要在这里使用一个.

或者,它也可以是散列构造函数.

sub f {
   ...
   if (@errors) {
      { status => 'error', errors => \@errors }
   } else {
      { status => 'ok' }
   }
}

是的缩写

sub f {
   ...
   if (@errors) {
      return { status => 'error', errors => \@errors };
   } else {
      return { status => 'ok' };
   }
}

Perl偷看了大括号,猜测它是裸循环还是哈希构造函数.既然你没有提供大括号的内容,我们分不清楚.

Answer 2

它通常是与使用的一招do,见章语句修饰在perlsyn.

可能是作者想要用next类似的东西跳出街区.