如何在字符串的所有可能位置插入字符？

Question

我想在字符串的每个可能位置插入一个char,除了start和end.例如

abc
I want to have 
a-bc
ab-c
a-b-c

以下是我的测试,但不正确:

procedure TForm1.Button2Click(Sender: TObject);
var
start, i,j,k,position,loop: integer;
laststart,lastend:integer;
c,item,stem:string;
str, prefix:string;
begin
str:='abcd';
memo1.clear;
memo1.Lines.Add(str);
laststart:=0;
lastend:=memo1.lines.count-1;
position:=0;
prefix:='';
loop:=0;
while loop<=length(str)-1 do
  begin

    for j:= laststart to lastend do
    begin
    item:=memo1.lines[j];
        for k:=length(item) downto 1 do
        begin
            if item[k]='-' then
            begin
            position:=j;
            break;
            end;
         end;  //for k
   prefix:=copy(item,1,position);
   stem:=copy(item,position+1, length(item));

        for start:=1 to length(stem)-1 do
        begin
        c:=prefix+copy(stem,1,start)+'-'+
        copy(stem, start+1,length(stem));
        memo1.lines.add(c);
        end;
     end; //for j
    laststart:=lastend+1;
    lastend:=memo1.Lines.Count-1;
inc(loop);
end; //end while

end;

它输出:

abcd
a-bcd
ab-cd
abc-d
a--bcd // not correct
a-b-cd
a-bc-d
ab--cd //incorrect
ab-c-d
abc--d  //incorrect
a--bc-d //incorrect

我觉得最大可能的中断是lenth(str)-1,abc->最可能的是插入2' - '(两次).它是否正确？

还有其他更快的方法吗？

非常感谢.

Answer 1

递归版.

  procedure InsertSymbols(s: string; c: Char; Position: Integer = 1);
  var
    i: Integer;
  begin
    Memo1.Lines.Add(s);
    for i := Position to Length(s) - 1 do
      InsertSymbols(Copy(s, 1, i) + c + Copy(s, i + 1, Length(s) - i), c, i + 2);
  end;

begin
  InsertSymbols('Test', '-');
end;

Answer 2

这有效:

procedure TForm4.Button1Click(Sender: TObject);
var
  S: string;
  N: integer;
  Marker: cardinal;
  MaxMarker: cardinal;
  Str: string;
  i: Integer;
begin
  S := Edit1.Text;
  N := length(S);
  Marker := 0;
  MaxMarker := 1 shl (N - 1) - 1;

  Memo1.Clear;
  Memo1.Lines.BeginUpdate;

  for Marker := 0 to MaxMarker do
  begin
    Str := S[1];
    for i := 2 to N do
    begin
      if (Marker shr (N-i)) and 1 <> 0 then
        Str := Str + '-';
      Str := Str + S[i];
    end;
    Memo1.Lines.Add(Str);
  end;

  Memo1.Lines.EndUpdate;
end;

截图http://privat.rejbrand.se/markersinstrallpos.png

如您所见,它通过使用数字的二进制表示来工作:

t e s t
 0 0 0
 0 0 1
 0 1 0
 0 1 1
 1 0 0
 1 0 1
 1 1 0
 1 1 1