着色当前行号

Question

我用的global-linum-mode是行号.如果用不同的颜色(和/或不同的背景)突出显示当前行的行号,那将是很好的.任何人都知道如何实现这一目标？

谢谢!

Answer 1

我从我之前对Emacs中相对行号的回答中得出了这个答案,因为它处理了在linum格式化过程中记住当前行号的相同问题.

我是从linum脸上继承的,但是使用的是背景颜色hl-line.如果前景和背景不匹配,则可以明确指定前景色
M-x customize-face RET my-linum-hl RET

(require 'hl-line)

(defface my-linum-hl
  `((t :inherit linum :background ,(face-background 'hl-line nil t)))
  "Face for the current line number."
  :group 'linum)

(defvar my-linum-format-string "%3d")

(add-hook 'linum-before-numbering-hook 'my-linum-get-format-string)

(defun my-linum-get-format-string ()
  (let* ((width (1+ (length (number-to-string
                             (count-lines (point-min) (point-max))))))
         (format (concat "%" (number-to-string width) "d")))
    (setq my-linum-format-string format)))

(defvar my-linum-current-line-number 0)

(setq linum-format 'my-linum-format)

(defun my-linum-format (line-number)
  (propertize (format my-linum-format-string line-number) 'face
              (if (eq line-number my-linum-current-line-number)
                  'my-linum-hl
                'linum)))

(defadvice linum-update (around my-linum-update)
  (let ((my-linum-current-line-number (line-number-at-pos)))
    ad-do-it))
(ad-activate 'linum-update)

与其他答案一样,这在生成动态宽度方面比默认dynamic格式更有效,但您可以通过注释掉行来使用静态宽度来获得最大速度(add-hook linum-before-numbering-hook 'my-linum-get-format-string)(并可选择修改初始值my-linum-format-string以设置首选宽度).

Answer 2

它可以通过hlinum扩展来实现.

(require 'hlinum)
(hlinum-activate)

您可以更改linum-highlight-face为自定义背景和前景色.