改变了如何构建Setup.hs

Question

该编码包使用了HaXml在构建脚本(中Setup.hs).碰巧使用在HaXml-1.19和HaXml-1.22之间改变的接口位.如果编码包能够使用任一版本构建,那将是很好的.我尝试使用通常的Cabal技巧,即做类似的事情

{-# LANGUAGE CPP #-}
#if MIN_VERSION_HaXml(1,22,0)
-- HaXml-1.22 code
#else
-- HaXml-1.19 code
#endif

...但是在配置包之前,魔术定义不可能存在,并且正在构建此文件以使配置步骤成为可能.我有什么选择？有没有办法更改cabal-install调用编译的命令Setup.hs？是否有其他机制可以有条件地选择回避cabal的代码？

Answer 1

该Data.Data接口能够（几乎！）构造和解构可能存在或不存在的类型的值。不幸的是，HaXml 似乎没有Data其类型的实例，并且您无法定义实例，因为您无法引用可能存在或可能不存在的类型，因此我们必须求助于 Template Haskell：

以下模块导出qnameCompat：

{-# LANGUAGE TemplateHaskell #-}
module HaXmlCompat (qnameCompat) where

import Language.Haskell.TH

qnameCompat :: Q [Dec]
qnameCompat = do
  mi <- maybeReify "N"
  case mi of
    Nothing -> sequence [
      tySynD (mkName "QName") [] [t| String |],
      valD [p| toQName |] (normalB [| id |]) [],
      valD [p| fromQName |] (normalB [| Just |]) []]
    Just (DataConI n _ _ _) -> do
      s <- newName "s"
      sequence [
        valD [p| toQName |] (normalB (conE n)) [],
        funD (mkName "fromQName") [
          clause [conP n [varP s]] (normalB (appE [| Just |] (varE s))) [],
          clause [ [p| _ |] ] (normalB [| Nothing |]) []]]
    Just i -> fail $
      "N exists, but isn't the sort of thing I expected: " ++ show i

maybeReify :: String -> Q (Maybe Info)
maybeReify = recover (return Nothing) . fmap Just . reify . mkName

当使用Template Haskell在顶层拼接时，qnameCompat将检查是否N存在。如果是，它会生成以下代码：

toQName = N
fromQName (N s) = Just s
fromQName _ = Nothing

如果没有，则会产生以下结果：

type QName = String
toQName = id
fromQName = Just

现在您可以创建和解构Elements，例如使用 ViewPatterns 扩展：

myElt :: String -> Element i
myElt = Elem (toQName "elemName") [] []

eltName :: Element i -> String
eltName (Elem (fromQName -> Just n) _ _) = n

当然，ViewPatterns 很方便，但不是必需的：对 的结果使用普通模式匹配也fromQName同样有效。

（这些想法促使我开发notcpp 包，其中包括maybeReify和其他一些有用的实用程序）