为什么不能将地址转换为64位Delphi中的嵌套本地函数？

Question

如.关闭相关问题 - 下面添加更多示例.

下面的简单代码(找到顶级Ie窗口并枚举其子代)与'32位Windows'目标平台一起正常工作.早期版本的Delphi也没有问题:

procedure TForm1.Button1Click(Sender: TObject);

  function EnumChildren(hwnd: HWND; lParam: LPARAM): BOOL; stdcall;
  const
    Server = 'Internet Explorer_Server';
  var
    ClassName: array[0..24] of Char;
  begin
    Assert(IsWindow(hwnd));            // <- Assertion fails with 64-bit
    GetClassName(hwnd, ClassName, Length(ClassName));
    Result := ClassName <> Server;
    if not Result then
      PUINT_PTR(lParam)^ := hwnd;
  end;

var
  Wnd, WndChild: HWND;
begin
  Wnd := FindWindow('IEFrame', nil); // top level IE
  if Wnd <> 0 then begin
    WndChild := 0;
    EnumChildWindows(Wnd, @EnumChildren, UINT_PTR(@WndChild));

    if WndChild <> 0 then
      ..    

end;

我插入了一个Assert用'64位Windows'目标平台来指示失败的地方.如果我取消嵌套回调,代码没有问题.

我不确定参数传递的错误值是否只是垃圾或是由于某些错误的内存地址(调用约定？).嵌套回调是不是我首先应该做的事情？或者这只是我必须忍受的缺陷？

编辑:
响应David的回答,EnumChildWindows使用类型回调声明了相同的代码.适用于32位:(

编辑:下面并没有真正测试大卫所说的,因为我仍然使用'@'运算符.它适用于运算符,但如果我删除它,它确实不会编译,除非我联合国 - 回调)

type
  TFNEnumChild = function(hwnd: HWND; lParam: LPARAM): Bool; stdcall;

function TypedEnumChildWindows(hWndParent: HWND; lpEnumFunc: TFNEnumChild;
    lParam: LPARAM): BOOL; stdcall; external user32 name 'EnumChildWindows';

procedure TForm1.Button1Click(Sender: TObject);

  function EnumChildren(hwnd: HWND; lParam: LPARAM): BOOL; stdcall;
  const
    Server = 'Internet Explorer_Server';
  var
    ClassName: array[0..24] of Char;
  begin
    Assert(IsWindow(hwnd));            // <- Assertion fails with 64-bit
    GetClassName(hwnd, ClassName, Length(ClassName));
    Result := ClassName <> Server;
    if not Result then
      PUINT_PTR(lParam)^ := hwnd;
  end;

var
  Wnd, WndChild: HWND;
begin
  Wnd := FindWindow('IEFrame', nil); // top level IE
  if Wnd <> 0 then begin
    WndChild := 0;
    TypedEnumChildWindows(Wnd, @EnumChildren, UINT_PTR(@WndChild));

    if WndChild <> 0 then
      ..

end;

---

实际上,这个限制并不是特定于Windows API回调,但是当将该函数的地址转换为变量procedural type并传递它时会发生同样的问题,例如,作为自定义比较器TList.Sort.

http://docwiki.embarcadero.com/RADStudio/XE4/en/Procedural_Types

procedure TForm2.btn1Click(Sender: TObject);
var s : TStringList;

  function compare(s : TStringList; i1, i2 : integer) : integer;
  begin
    result := CompareText(s[i1], s[i2]);
  end;

begin
  s := TStringList.Create;
  try
    s.add('s1');
    s.add('s2');
    s.add('s3');
    s.CustomSort(@compare);
  finally
    s.free;
  end;
end;

编译为32位时,它按预期工作,但Access Violation在为Win64编译时失败.对于64位版本的功能compare,s = nil 和i2=一些随机值;

如果在compare函数之外提取函数,它甚至可以按预期工作,即使对于Win64目标也是如此btn1Click.

Answer 1

这个技巧从未被语言正式支持,并且由于32位编译器的实现细节,您迄今为止已经开始使用它.该文件是明确的:

嵌套过程和函数(在其他例程中声明的例程)不能用作过程值.

如果我没记错的话,一个额外的隐藏参数会传递给嵌套函数,并带有指向封闭堆栈帧的指针.如果没有引用封闭环境,则在32位代码中省略.在64位代码中,总是传递额外参数.

当然,问题的很大一部分是Windows单元使用非类型化的过程类型作为其回调参数.如果使用了类型化的过程,编译器可能会拒绝您的代码.事实上,我认为这是相信你使用的技巧从来都不合法的理由.使用类型回调,即使在32位编译器中也不能使用嵌套过程.

无论如何,底线是你不能将嵌套函数作为参数传递给64位编译器中的另一个函数.