从电子表格数据创建文件夹层次结构

Question

我有几个电子表格，其中的数据从左到右组织，我想从中创建文件夹。每条记录都是完整的，没有空格，除非那是行的末尾，所以我正在寻找以下内容：

Col1     Col2     Col3
------   ------   ------
Car      Toyota   Camry
Car      Toyota   Corolla
Truck    Toyota   Tacoma
Car      Toyota   Yaris
Car      Ford     Focus
Car      Ford     Fusion
Truck    Ford     F150

Car
    Toyota
        Camry
        Corolla
        Yaris
    Ford
        Focus
        Fusion
Truck
    Toyota
        Tacoma
    Ford
        F-150
...

唯一需要注意的是，我有大约 15 列，有些条目在第 3 或 4 列结束，因此只需要创建那些文件夹。

任何人都可以帮助处理这个请求吗？我对编程并不陌生，但我对 VBA 还是很陌生。

谢谢！

Answer 1

Sub Tester()

    Const ROOT_FOLDER = "C:\TEMP\"
    Dim rng As Range, rw As Range, c As Range
    Dim sPath As String, tmp As String

    Set rng = Selection

    For Each rw In rng.Rows
        sPath = ROOT_FOLDER
        For Each c In rw.Cells
            tmp = Trim(c.Value)
            If Len(tmp) = 0 Then
                Exit For
            Else
                sPath = sPath & tmp & "\"
                If Len(Dir(sPath, vbDirectory)) = 0 Then MkDir sPath
            End If
        Next c
    Next rw
End Sub