从Win32从C或Delphi获取BIOS UUID

Question

VMWare配置文件包含一行

uuid.bios = "56 4d ed cf 3c cd 63 20-53 78 95 86 26 92 22 c8"

而afaik大多数(每个？)物理BIOS都有这样一个UUID.是否有任何Windows API调用来获取此标识符？

我已经尝试了WMI类Win32_ComputerSystemProduct.UUID属性,但该值与uuid.bios值不同.HKEY_LOCAL_MACHINE\Software\Microsoft\Cryptography\MachineGuid的值也不同.

Answer 1

这个值被称为Universal Unique ID number是SMBIOS表中的一部分,如果你使用Win32_BIOS WMI类的SerialNumber属性youu将获得的相同的ID uuid.bios(来自VMX文件)项加前缀VMware-(例如:VMware-56 4d af ac d8 bd 4d 2c-06 df ca af 89 71 44 93)

uses
  SysUtils,
  ActiveX,
  ComObj,
  Variants;

// The Win32_BIOS class represents the attributes of the computer system's basic input/output services (BIOS) that are installed on the computer.

procedure  GetWin32_BIOSInfo;
const
  WbemUser            ='';
  WbemPassword        ='';
  WbemComputer        ='localhost';
  wbemFlagForwardOnly = $00000020;
var
  FSWbemLocator : OLEVariant;
  FWMIService   : OLEVariant;
  FWbemObjectSet: OLEVariant;
  FWbemObject   : OLEVariant;
  oEnum         : IEnumvariant;
  iValue        : LongWord;
begin;
  FSWbemLocator := CreateOleObject('WbemScripting.SWbemLocator');
  FWMIService   := FSWbemLocator.ConnectServer(WbemComputer, 'root\CIMV2', WbemUser, WbemPassword);
  FWbemObjectSet:= FWMIService.ExecQuery('SELECT SerialNumber FROM Win32_BIOS','WQL',wbemFlagForwardOnly);
  oEnum         := IUnknown(FWbemObjectSet._NewEnum) as IEnumVariant;
  if oEnum.Next(1, FWbemObject, iValue) = 0 then
    Writeln(Format('SerialNumber    %s',[String(FWbemObject.SerialNumber)]));// String
end;


begin
 try
    CoInitialize(nil);
    try
      GetWin32_BIOSInfo;
    finally
      CoUninitialize;
    end;
 except
    on E:EOleException do
        Writeln(Format('EOleException %s %x', [E.Message,E.ErrorCode])); 
    on E:Exception do
        Writeln(E.Classname, ':', E.Message);
 end;
 Writeln('Press Enter to exit');
 Readln;      
end.

如果你想要返回没有VMware- 前缀的同一个uuid, 你必须直接读取SMBIOS表(检查系统信息表类型1和UUID字段),试试这篇文章Reading the SMBios Tables using Delphiwhcih include有一个示例代码来列出这个值.

UUID格式

来自 System Management BIOS (SMBIOS) Reference Specification

UUID是一种设计为在时间和空间上都是唯一的标识符.它不需要中央注册过程.UUID长128位.其格式在RFC 4122中描述,但实际的字段内容是不透明的,对SMBIOS规范并不重要,SMBIOS规范仅涉及字节顺序.表10显示了字段名称; 这些字段名称,特别是多路复用字段,遵循历史惯例.

尽管RFC 4122建议所有字段的网络字节顺序,但PC行业(包括ACPI,UEFI和Microsoft规范)始终对前三个字段使用little-endian字节编码:time_low,time_mid,time_hi_and_version.同样的编码(也称为有线格式)也应该用于UUID的SMBIOS表示.

因此,UUID {00112233-4455-6677-8899-AABBCCDDEEFF}将表示为:33 22 11 00 55 44 77 66 88 99 AA BB CC DD EE FF.

如果该值全部为FFh,则系统中当前不存在该ID,但可以设置该ID.如果该值全部为00h,则系统中不存在该ID.