加载Jpg/Gif/Bitmap并转换为Bitmap

Question

我必须从XML文件加载图像.XML文件中没有关于图像是否为JPG/GIF/BMP的信息.加载图像后,我需要将其转换为Bitmap.

有没有人知道如何在不知道实际文件格式的情况下将图像转换为Bitmap？我正在使用Delphi 2007/2009

谢谢.

Answer 1

Delphi 2009内置支持JPEG,BMP,GIF和PNG.

对于早期版本的Delphi,你可能需要找到PNG和GIF第三方实现,但德尔福2009年,你只需添加Jpeg,pngimage和GIFImg单位的使用条款.

如果文件有扩展名,您可以使用以下代码,如其他人所述,TPicture.LoadFromFile查看继承类注册的扩展名以确定要加载的图像.

uses
  Graphics, Jpeg, pngimage, GIFImg;

procedure TForm1.Button1Click(Sender: TObject);
var
  Picture: TPicture;
  Bitmap: TBitmap;
begin
  Picture := TPicture.Create;
  try
    Picture.LoadFromFile('C:\imagedata.dat');
    Bitmap := TBitmap.Create;
    try
      Bitmap.Width := Picture.Width;
      Bitmap.Height := Picture.Height;
      Bitmap.Canvas.Draw(0, 0, Picture.Graphic);
      Bitmap.SaveToFile('C:\test.bmp');
    finally
      Bitmap.Free;
    end;
  finally
    Picture.Free;
  end;
end;

如果文件扩展名未知,则一种方法是查看前几个字节以确定图像类型.

procedure DetectImage(const InputFileName: string; BM: TBitmap);
var
  FS: TFileStream;
  FirstBytes: AnsiString;
  Graphic: TGraphic;
begin
  Graphic := nil;
  FS := TFileStream.Create(InputFileName, fmOpenRead);
  try
    SetLength(FirstBytes, 8);
    FS.Read(FirstBytes[1], 8);
    if Copy(FirstBytes, 1, 2) = 'BM' then
    begin
      Graphic := TBitmap.Create;
    end else
    if FirstBytes = #137'PNG'#13#10#26#10 then
    begin
      Graphic := TPngImage.Create;
    end else
    if Copy(FirstBytes, 1, 3) =  'GIF' then
    begin
      Graphic := TGIFImage.Create;
    end else
    if Copy(FirstBytes, 1, 2) = #$FF#$D8 then
    begin
      Graphic := TJPEGImage.Create;
    end;
    if Assigned(Graphic) then
    begin
      try
        FS.Seek(0, soFromBeginning);
        Graphic.LoadFromStream(FS);
        BM.Assign(Graphic);
      except
      end;
      Graphic.Free;
    end;
  finally
    FS.Free;
  end;
end;

Answer 2

我找到了一种更简单的方法!它自动加载JPG/GIF/BMP等文件,甚至不知道/检查文件格式,并相应地转换它.它对我很有帮助.

在这里分享:)

Uses
Classes, ExtCtrls, Graphics, axCtrls;

Procedure TForm1.Button1Click(Sender: TObject);
Var
     OleGraphic               : TOleGraphic;
     fs                       : TFileStream;
     Source                   : TImage;
     BMP                      : TBitmap;
Begin
     Try
          OleGraphic := TOleGraphic.Create; {The magic class!}

          fs := TFileStream.Create('c:\testjpg.dat', fmOpenRead Or fmSharedenyNone);
          OleGraphic.LoadFromStream(fs);

          Source := Timage.Create(Nil);
          Source.Picture.Assign(OleGraphic);

          BMP := TBitmap.Create; {Converting to Bitmap}
          bmp.Width := Source.Picture.Width;
          bmp.Height := source.Picture.Height;
          bmp.Canvas.Draw(0, 0, source.Picture.Graphic);

          image1.Picture.Bitmap := bmp; {Show the bitmap on form}
     Finally
          fs.Free;
          OleGraphic.Free;
          Source.Free;
          bmp.Free;
     End;
End;

Answer 3

TPicture.LoadFromFile如果您不知道图形的格式,则无法使用,因为此方法使用文件扩展名来确定需要加载哪些已注册的图形格式.有一个原因是没有匹配的TPicture.LoadFromStream方法.

可以在运行时检查数据并确定图形格式的外部库是最佳解决方案.您可以使用efg页面作为研究的起点.

一个快速而肮脏的解决方案是尝试您需要处理的几种格式,直到成功为止:

function TryLoadPicture(const AFileName: string; APicture: TPicture): boolean;
const
  GraphicClasses: array[0..3] of TGraphicClass = (
    TBitmap, TJPEGImage, TGIFImage, TPngImage);
var
  FileStr, MemStr: TStream;
  ClassIndex: integer;
  Graphic: TGraphic;
begin
  Assert(APicture <> nil);
  FileStr := TFileStream.Create('D:\Temp\img.dat', fmOpenRead);
  try
    MemStr := TMemoryStream.Create;
    try
      MemStr.CopyFrom(FileStr, FileStr.Size);
      // try various
      for ClassIndex := Low(GraphicClasses) to High(GraphicClasses) do begin
        Graphic := GraphicClasses[ClassIndex].Create;
        try
          try
            MemStr.Seek(0, soFromBeginning);
            Graphic.LoadFromStream(MemStr);
            APicture.Assign(Graphic);
            Result := TRUE;
            exit;
          except
          end;
        finally
          Graphic.Free;
        end;
      end;
    finally
      MemStr.Free;
    end;
  finally
    FileStr.Free;
  end;
  Result := FALSE;
end;

编辑:

该GraphicEx库有一个例子转换使用

GraphicClass := FileFormatList.GraphicFromContent(...);

确定图形格式.这看起来非常类似于你提到的VB6这样做的方式.也许您可以将此库用于您的目的.

Answer 4

我没有Delphi 2007或2009,看看这是否适用于这两个版本.但是,在XE2中,还有另一个Vcl.Graphics被调用的类TWICImage来处理Microsoft Imaging Component支持的图像,包括BMP,GIF,ICO,JPEG,PNG,TIF和Windows Media Photo.它能够从流中检测图像类型.假设您TImage在名为Image1的表单上有一个:

procedure LoadImageFromStream(Stream: TStream; Image: TImage);
var
  wic: TWICImage;
begin
  Stream.Position := 0;
  wic := TWICImage.Create;
  try
    wic.LoadFromStream(Stream);
    Image.Picture.Assign(wic);
  finally
    wic.Free;
  end;
end;

procedure RenderImage(const Filename: string);
var
  fs: TFileStream;
begin
  fs := TFileStream.Create(Filename, fmOpenRead);
  try
    LoadImageFromStream(fs, Image1);
  finally
    fs.Free;
  end;
end;

它可以在不添加PNGImage,GIFImg或者JPEG您的uses声明的情况下工作.

其他答案显示如何将其转换TImage为BMP,所以我不在此处.我只是展示另一种方法将各种图形类型加载到一个TImage事先不知道图像类型或文件扩展名...