没有OnExecute事件的TCP服务器

Question

我想打一个TCPserver下和发送/接收邮件的客户需要的TCPserver下的,不OnExecute事件.

发送/接收消息不是问题; 我喜欢这样:

procedure TFormMain.SendMessage(IP, Msg: string);
var
  I: Integer;
begin
  with TCPServer.Contexts.LockList do
  try
    for I := 0 to Count-1 do
      if TIdContext(Items[I]).Connection.Socket.Binding.PeerIP = IP then
      begin
        TIdContext(Items[I]).Connection.IOHandler.WriteBuffer(Msg[1], Length(Msg));
        //  and/or Read 
        Break;
      end;
  finally
    TCPServer.Contexts.UnlockList;
  end;
end;

注1:如果我不使用OnExecute,程序会在客户端连接时引发异常.
注意2:如果我在不做任何事情的情况下使用OnExecute,则CPU使用率将达到%100
注3:我没有机会更改TCP客户端.

所以我该怎么做？

Answer 1

TIdTCPServer需要OnExecute默认分配的事件处理程序.要解决这个问题,您必须从中派生一个新类TIdTCPServer并覆盖其虚CheckOkToBeActive()方法,并且还应该覆盖DoExecute()要调用的虚拟方法Sleep().否则,只需分配一个事件处理程序并让它调用Sleep().

但是,这不是一种有效的用途TIdTCPServer.更好的设计是不要SendMessage()直接从方法内部将出站数据写入客户端.在写入期间,不仅容易出错(您没有捕获异常WriteBuffer())和块SendMessage(),而且它还会序列化您的通信(客户端2在客户端1执行之前无法接收数据).更有效的设计是为每个客户端提供自己的线程安全出站队列,然后根据需要SendMessage()将数据放入每个客户端的队列中.然后,您可以使用该OnExecute事件检查每个客户端的队列并进行实际写入.这样,SendMessage()不会再被阻塞,更不容易出错,并且可以并行编写客户端(就像它们应该的那样).

尝试这样的事情:

uses
  ..., IdThreadSafe;

type
  TMyContext = class(TIdServerContext)
  private
    FQueue: TIdThreadSafeStringList;
    FEvent: TEvent;
  public
    constructor Create(AConnection: TIdTCPConnection; AYarn: TIdYarn; AList: TThreadList = nil); override;
    destructor Destroy; override;
    procedure AddMsgToQueue(const Msg: String);
    function GetQueuedMsgs: TStrings;
  end;

constructor TMyContext.Create(AConnection: TIdTCPConnection; AYarn: TIdYarn; AList: TThreadList = nil);
begin
  inherited;
  FQueue := TIdThreadSafeStringList.Create;
  FEvent := TEvent.Create(nil, True, False, '');
end;

destructor TMyContext.Destroy;
begin
  FQueue.Free;
  FEvent.Free;
  inherited;
end;

procedure TMyContext.AddMsgToQueue(const Msg: String);
begin
  with FQueue.Lock do
  try
    Add(Msg);
    FEvent.SetEvent;
  finally
    FQueue.Unlock;
  end;
end;

function TMyContext.GetQueuedMsgs: TStrings;
var
  List: TStringList;
begin
  Result := nil;
  if FEvent.WaitFor(1000) <> wrSignaled then Exit;
  List := FQueue.Lock;
  try
    if List.Count > 0 then
    begin
      Result := TStringList.Create;
      try
        Result.Assign(List);
        List.Clear;
      except
        Result.Free;
        raise;
      end;
    end;
    FEvent.ResetEvent;
  finally
    FQueue.Unlock;
  end;
end;

procedure TFormMain.FormCreate(Sender: TObject);
begin
  TCPServer.ContextClass := TMyContext;
end; 

procedure TFormMain.TCPServerExecute(AContext: TIdContext);
var
  List: TStrings;
  I: Integer;
begin
  List := TMyContext(AContext).GetQueuedMsgs;
  if List = nil then Exit;
  try
    for I := 0 to List.Count-1 do
      AContext.Connection.IOHandler.Write(List[I]);
  finally
    List.Free;
  end;
end;

procedure TFormMain.SendMessage(const IP, Msg: string); 
var 
  I: Integer; 
begin 
  with TCPServer.Contexts.LockList do 
  try 
    for I := 0 to Count-1 do 
    begin
      with TMyContext(Items[I]) do
      begin
        if Binding.PeerIP = IP then 
        begin 
          AddMsgToQueue(Msg); 
          Break; 
        end;
      end; 
    end;
  finally 
    TCPServer.Contexts.UnlockList; 
  end; 
end;