在listBox中搜索指定的字符串VB6

Question

我有一个名为lstSerial的列表框和一个名为txtSerials的文本框.我想要做的是搜索lstSerial以获取在txtSerials中输入的字符串.我在Microsoft Visual Basic 6.0中使用VB6,而且我很难找到文档.

谢谢.

Answer 1

@ AlexK的回答在技术上是正确的 - 是的 - 它会起作用,但它不是首选的方式.为此目的有一个API调用:

Private Declare Function SendMessage Lib "USER32" Alias "SendMessageA" _
     (ByVal hWnd As Long, ByVal wMsg As Long, ByVal wParam As _
     Integer, ByVal lParam As Any) As Long

'constants for searching the ListBox
Private Const LB_FINDSTRINGEXACT = &H1A2
Private Const LB_FINDSTRING = &H18F

'function to get find an item in the Listbox
Public Function GetListBoxIndex(hWnd As Long, SearchKey As String, Optional FindExactMatch As Boolean = True) As Long

    If FindExactMatch Then
        GetListBoxIndex = SendMessage(hWnd, LB_FINDSTRINGEXACT, -1, ByVal SearchKey)
    Else
        GetListBoxIndex = SendMessage(hWnd, LB_FINDSTRING, -1, ByVal SearchKey)
    End If

End Function

所以你想这样做:

lstSerial.ListIndex = GetListBoxIndex(lstSerial.hWnd, txtSerials.Text)

资源

Answer 2

文档; http://msdn.microsoft.com/en-us/library/aa267225(v=VS.60).aspx

dim find as string,i as long,found as boolean
find=txtSerials.text

for i=0 to lstserial.listcount - 1
    if strcomp(find, lstSerial.list(i), vbTextcompare)=0 then
        found = true
        lstSerial.setfocus
        lstSerial.listindex= i
        exit for
    end if
next

if not found then msgbox "not found ..."