如何用GLSL改变纹理的色调？

Question

有没有办法使用GLSL(片段着色器)有效地改变2D OpenGL纹理的色调？

有人有一些代码吗？

更新:这是user1118321建议的代码:

uniform sampler2DRect texture;
const mat3 rgb2yiq = mat3(0.299, 0.587, 0.114, 0.595716, -0.274453, -0.321263, 0.211456, -0.522591, 0.311135);
const mat3 yiq2rgb = mat3(1.0, 0.9563, 0.6210, 1.0, -0.2721, -0.6474, 1.0, -1.1070, 1.7046);
uniform float hue;

void main() {

vec3 yColor = rgb2yiq * texture2DRect(texture, gl_TexCoord[0].st).rgb; 

float originalHue = atan(yColor.b, yColor.g);
float finalHue = originalHue + hue;

float chroma = sqrt(yColor.b*yColor.b+yColor.g*yColor.g);

vec3 yFinalColor = vec3(yColor.r, chroma * cos(finalHue), chroma * sin(finalHue));
gl_FragColor    = vec4(yiq2rgb*yFinalColor, 1.0);
}

这是与参考相比的结果:

我试图在里面用Q切换I,但即使在0°左右,结果也是错误的

你有什么提示吗？

如果需要进行比较,这是原始未修改的图像:

Answer 1

虽然@awoodland所说的是正确的,但我相信这种方法可能会引起亮度变化的问题.

出于多种原因,HSV和HLS颜色系统存在问题.我最近和一位色彩科学家谈过这个问题,他的建议是转换到YIQ或YCbCr空间并相应地调整色度通道(I&Q,或Cb&Cr).(你可以在这里和这里学习如何做到这一点.)

一旦进入其中一个空间,您就可以从色度通道形成的角度获得色调hue = atan(cr/cb)(通过观察cb == 0).这给你一个弧度值.只需通过添加色调旋转量来旋转它.完成后,您可以计算色度的大小chroma = sqrt(cr*cr+cb*cb).要回到RGB,计算使用新Cb和Cr(或I&Q) ,.Cr = chroma * sin (hue) Cb = chroma * cos (hue)然后转换回RGB,如上面的网页所述.

编辑:这是我已经测试过的解决方案,似乎给了我与你的参考相同的结果.您可以将一些点积折叠成矩阵乘法:

uniform sampler2DRect inputTexture;
uniform float   hueAdjust;
void main ()
{
    const vec4  kRGBToYPrime = vec4 (0.299, 0.587, 0.114, 0.0);
    const vec4  kRGBToI     = vec4 (0.596, -0.275, -0.321, 0.0);
    const vec4  kRGBToQ     = vec4 (0.212, -0.523, 0.311, 0.0);

    const vec4  kYIQToR   = vec4 (1.0, 0.956, 0.621, 0.0);
    const vec4  kYIQToG   = vec4 (1.0, -0.272, -0.647, 0.0);
    const vec4  kYIQToB   = vec4 (1.0, -1.107, 1.704, 0.0);

    // Sample the input pixel
    vec4    color   = texture2DRect (inputTexture, gl_TexCoord [ 0 ].xy);

    // Convert to YIQ
    float   YPrime  = dot (color, kRGBToYPrime);
    float   I      = dot (color, kRGBToI);
    float   Q      = dot (color, kRGBToQ);

    // Calculate the hue and chroma
    float   hue     = atan (Q, I);
    float   chroma  = sqrt (I * I + Q * Q);

    // Make the user's adjustments
    hue += hueAdjust;

    // Convert back to YIQ
    Q = chroma * sin (hue);
    I = chroma * cos (hue);

    // Convert back to RGB
    vec4    yIQ   = vec4 (YPrime, I, Q, 0.0);
    color.r = dot (yIQ, kYIQToR);
    color.g = dot (yIQ, kYIQToG);
    color.b = dot (yIQ, kYIQToB);

    // Save the result
    gl_FragColor    = color;
}