如何在可视模式下在外部过滤器命令中使用vim变量？

Question

我正在尝试使代码漂亮的打印机过滤器(例如perltidy)接受任意选项,具体取决于vim变量.我的目标是将项目特定选项传递给在可视模式下用作过滤器(:!)的外部命令.

以下表达了我的意图(最后一行有问题):

" set b:perltidy_options based on dirname of the currently edited file
function! SetProjectVars()
  if match(expand("%:p:h"), "/project-foo/") >= 0
    let b:perltidy_options = "--profile=$HOME/.perltidyrc-foo --quiet"
  elseif match(expand("%:p:h"), "/project-bar/") >= 0
    let b:perltidy_options = "--profile=$HOME/.perltidyrc-bar --quiet"
  else
    let b:perltidy_options = "--quiet"
  endif
endfunction

" first set the project specific stuff
autocmd BufRead,BufNewFile * call SetProjectVars()

" then use it
vnoremap ,t :execute "!perltidy " . b:perltidy_options<Enter>

但是,最后一行(vnoremap)是vim中的错误,因为它扩展为:

:'<,'>execute "!perltidy " . b:perltidy_options

并且execute命令不能接受范围.但我想要这个:

:execute "'<,'>!perltidy " . b:perltidy_options

我怎样才能做到这一点？

ps我的perltidy被配置为像unix过滤器一样,我使用vim 7.3.

Answer 1

您可以使用<C-\>e和getcmdline()来保留命令行内容：

vnoremap ,t :<C-\>e'execute '.string(getcmdline()).'."!perltidy " . b:perltidy_options'<CR><CR>

，但在这种情况下，我建议更简单，<C-r>=从而消除了以下需要:execute：

vnoremap ,t :!perltidy <C-r>=b:perltidy_options<CR><CR>