Grails 2.0单元测试自定义标签库

Question

我有一个我编写的自定义标记库,以便我可以轻松地显示对象的属性.它允许我打电话

<g:property label="Name" property="${user.name}"/>

这使我的观点简短而一致,并允许我快速进行更改.我的taglib代码如下:

def property = {attrs, body ->
    def startingHtml = "..."
    def endingHtml = "..."

    out << startingHtml
    renderField(attrs.property)
    out << endingHtml
}

def renderField(property) {
    if (property instanceof Collection) {
        property.each { out << it + "</br>" }
    } else if(property instanceof Address){
        renderAddress(property)
    } else {
        out << property
    }
}

def renderAddress(address) {
    out << "Address Render Logic Here"
}

我试图在这段代码中添加一些单元测试,因为它有逻辑.使用此处的示例(http://grails.org/doc/latest/guide/testing.html#unitTestingTagLibraries),我开始添加一些测试.我的标签当前处理的前两个场景是String和Collection,我能够正确测试(下面的前两个测试).我需要测试的最后一个场景是Address对象(它只是一个带有String属性的POGO).我似乎无法找到一种方法来测试将对象作为属性传递到标记lib中.

@TestFor(PropertyTagLib)
class PropertyTagLibTests {

@Test
void propertyTagShouldRenderPropertyInsideOfTDWhenPropertyIsAString() {
    String result = applyTemplate('<g:property label="something" property="someTextValue"/>').trim()

    assert result.contains('someTextValue')
}

@Test
void propertyTagShouldRenderList() {
    String result = applyTemplate('g:property label="something" property="[\"one\", \"two\", \"three\"]"/>').trim()

    assert result.contains("one</br>two</br>three</br>")
}

@Test
void propertyTagShouldRenderPropertyInsideOfTDWhenPropertyIsAnAddress() {
    def address = new Address(line1: "Line 1")
    String result = applyTemplate('<g:property label="something" property="${address}"/>').trim()

    assert result.contains("Address Render Logic Here")
}
}

当其中一个属性是对象时,如何测试我的taglib？

Answer 1

applyTemplate()的声明如下:

String applyTemplate(String contents, Map model = [:])

标签参数通过model.

您的测试可能如下所示:

@Test
void propertyTagShouldRenderPropertyInsideOfTDWhenPropertyIsAnAddress() {
    String result = applyTemplate('<g:property label="something" property="${address}"/>', [address : new Address(line1: "Line 1")]).trim()

    assert result.contains("Address Render Logic Here")
}