Synopse SQLite为1:N关系选择行

Question

我正在使用Synopse的SQLite实现,但我仍然坚持使用以下代码.在窗体的构造我创造一个有两个表的数据库模型Task,并Comment与一个表TaskComments有关系的1:N的任务的意见.我可以将行添加到TaskComments表中(Button1.OnClick事件为它添加一个任务和两个注释)但我不知道如何获取此任务的注释.

任何人都可以建议我如何获得某一行的N行(在这种情况下如何获得任务的评论)？

unit SynopseSQLiteTestUnit;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, SynCommons, SQLite3, SQLite3Commons, StdCtrls;

type
  TTask = class(TSQLRecord)
  private
    FTaskName: RawUTF8;
    FTaskCreated: TDateTime;
  published
    property TaskName: RawUTF8 read FTaskName write FTaskName;
    property TaskCreated: TDateTime read FTaskCreated write FTaskCreated;
  end;

  TComment = class(TSQLRecord)
  private
    FCommentText: RawUTF8;
    FCommentCreated: TDateTime;
  published
    property CommentText: RawUTF8 read FCommentText write FCommentText;
    property CommentCreated: TDateTime read FCommentCreated write FCommentCreated;
  end;

  TTaskComments = class(TSQLRecordMany)
  private
    FTask: TTask;
    FComment: TComment;
  published
    property Task: TTask read FTask;
    property Comment: TComment read FComment;
  end;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Button2: TButton;
    Memo1: TMemo;
    Memo2: TMemo;
    Memo3: TMemo;
    procedure FormCreate(Sender: TObject);
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
  private
    FDatabase: TSQLRestClientURI;
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.FormCreate(Sender: TObject);
var
  SQLModel: TSQLModel;
begin
  SQLModel := TSQLModel.Create([
    TTask,
    TComment,
    TTaskComments
  ]);
  FDatabase := TSQLRestClientDB.Create(SQLModel, SQLModel, ChangeFileExt(Application.ExeName,'.db3'), TSQLRestServerDB);
  TSQLRestClientDB(FDatabase).Server.CreateMissingTables(0);
end;

procedure TForm1.Button1Click(Sender: TObject);
var
  Task: TTask;
  TaskID: Integer;
  Comment: TComment;
  CommentID: Integer;
  TaskComments: TTaskComments;
begin
  Task := TTask.Create;
  Comment := TComment.Create;
  TaskComments := TTaskComments.Create;

  try
    Task.TaskName := StringToUTF8('Task Name');
    Task.TaskCreated := Now;
    TaskID := FDatabase.Add(Task, True);

    Comment.CommentText := StringToUTF8('Comment Text 1');
    Comment.CommentCreated := Now;
    CommentID := FDatabase.Add(Comment, True);

    TaskComments.ManyAdd(FDatabase, TaskID, CommentID);

    Comment.CommentText := StringToUTF8('Comment Text 2');
    Comment.CommentCreated := Now;
    CommentID := FDatabase.Add(Comment, True);

    TaskComments.ManyAdd(FDatabase, TaskID, CommentID, True);

  finally
    FreeAndNil(Task);
    FreeAndNil(Comment);
    FreeAndNil(TaskComments);
  end;
end;

procedure TForm1.Button2Click(Sender: TObject);
var
  Task: TTask;
  Comment: TComment;
  TaskComments: TTaskComments;
begin
  Memo1.Clear;
  Memo2.Clear;
  Memo3.Clear;

  // here I want to select task with ID = 1, that's fine
  Task := TTask.CreateAndFillPrepare(FDatabase, 'ID = 1');
  // here I want to select all comments, that's fine
  Comment := TComment.CreateAndFillPrepare(FDatabase, '');
  // here I want to create the task comments, ok
  TaskComments := TTaskComments.Create;

  try
    // here I'm filling the memo boxes with the task and all comments, ok
    while Task.FillOne do
      Memo1.Lines.Add(UTF8ToWideString(Task.TaskName));
    while Comment.FillOne do
      Memo2.Lines.Add(UTF8ToWideString(Comment.CommentText));

    // here I'm trying to get all comments for task with ID = 1
    // but the FillOne function returns always False, what means, that
    // I don't get any row fetched
    TaskComments.FillMany(FDatabase, 1);
    while TaskComments.FillOne do
      Memo3.Lines.Add(UTF8ToWideString(TaskComments.Task.TaskName) + '; ' + UTF8ToWideString(TaskComments.Comment.CommentText));

  finally
    FreeAndNil(Task);
    FreeAndNil(Comment);
    FreeAndNil(TaskComments);
  end;
end;

end.

非常感谢

Answer 1

你应该把它发布在官方的mORMot论坛上,这个日子里没有像其他土拨鼠一样睡觉......但是很高兴在SO中看到这样的问题!

首先,一些一般性说明:

• 你应该更好地使用UTF8ToString而不是UTF8ToWideString功能;
• 如果你创建对象实例,你最好使用嵌套try..finally块:例如,如果TComment.CreateAndPrepare构造函数失败并引发异常,你将永远不会到达FreeAndNil(Task)代码,所以你会泄漏内存;
• 请注意,FreeAndNil()在Delphi社区中使用非常危险 - 您可能会被解剖!
• 主要FSQLModel应公开,并在所有数据库时间内生效;
• 的TSQLRestClientDB三维参数(服务器模型)应该是零;
• FormDestroy需要A 才能释放内存,但这不是重点;

关于你的代码,事实上,正如文件指出,一个TSQLRecordMany子类应至少有两个发布的属性,命名Source和Dest,按照惯例:

• 默认情况下,只能创建两个TSQLRecord(即INTEGER)字段,名为"Source"和"Dest",第一个指向源记录(具有TSQLRecordMany发布属性的记录),第二个指向目标记录...
• 在所有情况下,在leat两个'Source'和'Dest'发布的属性必须在任何TSQLRecordMany后代中声明为TSQLRecord子节点,因为它们总是需要'many to many'关系

然后,它应该按预期工作:

  TTaskComments = class(TSQLRecordMany)
  private
    FSource: TTask;
    FDest: TComment;
  published
    property Source: TTask read FSource;
    property Dest: TComment read FDest;
  end;

请注意,该FillMany()方法仅填充Source和Dest作为ID,因此您不能直接获取Source.TaskName或Dest.CommentText.您将不得不使用例如DestGetJoined方法来检索所需的字段.看到的文档有关的方法,或读取TestMany在程序TTestSQLite3Engine._TSQLRestClientDB中的方法SQLite3.pas单位.

您还可以查看"自动连接查询"新功能(在1.16主干中):它将为您提供查询.看到这篇文章.