"Droplet"批处理脚本 - 包含&符号的文件名

Question

我正在尝试创建一个可以将其他文件放到其上的批处理文件.具体来说,我正在使用ffmpeg来编辑手持录音机产生的音频文件.问题是当使用带有&符号的文件名时(&).即使在引用输入时,&之后的任何内容都会被删除,但只有当文件被丢弃时才会被删除; 如果在命令行输入文件名输入,则脚本可以正常工作.在cmd窗口关闭之前,我会短暂地看到文件名的其余部分,并显示一条错误消息,说明它未被识别为有效命令.

这是我的脚本:

rem Change to drive and directory of input file
%~d1
cd %~p1

rem ffmpeg: mix to one channel, double the volume
%HOMEDRIVE%%HOMEPATH%\ffmpeg.exe -i "%~nx1" -ac 1 -vol 1024 "%~n1 fixed%~x1"

pause

这是删除后命令行上显示的内容"ch17&18.mp3":

C:\Users\computergeeksjw\Desktop>C:\Users\computergeeksjw\ffmpeg.exe -i "ch17" -ac 1 -vol 1024 "ch17 fixed"
[...]
ch17: No such file or directory

如果重要:我正在使用Windows 8开发人员预览版.这会导致我的问题吗？Windows 7或更早版本是否会出现相同的错误？

Answer 1

Windows拖放功能中存在一个长期存在的错误,涉及包含&或^不包含的文件路径<space>.

如果文件路径至少包含一个<space>,则Windows会自动将路径括在引号中,以便正确解析.如果文件路径包含&或^,Windows应该做同样的事情,但事实并非如此.

如果您创建以下简单批处理文件并将文件拖到其上,则可以看到问题.

@echo off
setlocal enableDelayedExpansion
echo cmd=!cmdcmdline!
echo %%1="%~1"
pause
exit

!cmdcmdline!变量包含启动批处理文件的实际命令.批处理文件打印出命令行和第一个参数.

如果你拖放一个名为"a.txt"的文件,你就得到了

cmd=cmd /c ""C:\test\drag.bat" C:\test\a.txt"
%1=C:\test\a.txt
Press any key to continue . . .

如果忽略整个命令的引号,则会看到文件参数周围没有引号.没有特殊字符,所以没有问题.

现在拖放"a b.txt"就可以了

cmd=cmd /c ""C:\test\drag.bat" "C:\test\a b.txt""
%1="C:\test\a b.txt"
Press any key to continue . . .

您可以看到Windows如何检测名称中的空格并将文件用引号括起来.再次没有问题.

现在拖放"a&b.txt"就可以了

cmd=cmd /c ""C:\test\drag.bat" C:\test\a&b.txt"
%1=C:\test\a
Press any key to continue . . .

Windows在名称中找不到空格,因此不会将其括在引号中.大问题!Windows将"C:\ test\a"传递给批处理文件,并将"b.txt"视为批处理文件完成后要执行的第二个文件.批处理文件中的硬EXIT命令可防止批处理后执行任何拆分文件名.当然b.txt永远不会执行.但是如果文件名为"a&b.bat"并且"b.bat"存在,那么如果硬EXIT不在批处理文件中,则可能会出现问题.

可以将多个文件拖到批处理文件中,并且每个文件都应作为参数传递.

!cmdcmdline!是可靠地访问拖放参数的唯一方法.但是,如果在批处理文件的正常调用中将文件作为普通参数传递,则无效.

下面是一个批处理文件,可以检测是否使用拖放与正常调用进行调用.(这不是防弹,但我认为它应该适用于大多数情况)它将处理每个文件参数,一次一个,无论调用类型如何.(该过程只是回显文件名,但您可以替换您想要的任何处理.)如果使用拖放调用批处理,则它将执行硬退出以防止拆分文件名.

@echo off
setlocal disableDelayedExpansion
::
:: first assume normal call, get args from %*
set args=%*
set "dragDrop="
::
:: Now check if drag&drop situation by looking for %0 in !cmdcmdline!
:: if found then set drag&drop flag and get args from !cmdcmdline!
setlocal enableDelayedExpansion
set "cmd=!cmdcmdline!"
set "cmd2=!cmd:*%~f0=!"
if "!cmd2!" neq "!cmd!" (
  set dragDrop=1
  set "args=!cmd2:~0,-1! "
  set "args=!args:* =!"
)
::
:: Process the args
for %%F in (!args!) do (
  if "!!"=="" endlocal & set "dragDrop=%dragDrop%"
  rem ------------------------------------------------
  rem - Your file processing starts here.
  rem - Each file will be processed one at a time
  rem - The file path will be in %%F
  rem -
  echo Process file "%%~F"
  rem -
  rem - Your file processing ends here
  rem -------------------------------------------------
)
::
:: If drag&drop then must do a hard exit to prevent unwanted execution
:: of any split drag&drop filename argument
if defined dragDrop (
  pause
  exit
)

看起来您的现有批次仅用于处理一个文件.我不知道你是否需要修改支持多个文件的调用.我修改了上面的批处理只处理第一个参数,并将你的进程替换为参数处理循环.这是未经测试的,但我认为它应该对你有用.

@echo off
setlocal disableDelayedExpansion
::
:: first assume normal call, get args from %*
set args=%*
set "dragDrop="
::
:: Now check if drag&drop situation by looking for %0 in !cmdcmdline!
:: if found then set drag&drop flag and get args from !cmdcmdline!
setlocal enableDelayedExpansion
set "cmd=!cmdcmdline!"
set "cmd2=!cmd:*%~f0=!"
if "!cmd2!" neq "!cmd!" (
  set dragDrop=1
  set "args=!cmd2:~0,-1! "
  set "args=!args:* =!"
)
::
:: Process the first argument only
for %%F in (!args!) do (
  if "!!"=="" endlocal & set "dragDrop=%dragDrop%"
  rem ------------------------------------------------
  rem - Your file processing starts here.
  rem - Use %%F wherever you would normally use %1
  rem
  rem Change to drive and directory of input file
  %%~dF
  cd %%~pF
  rem ffmpeg: mix to one channel, double the volume
  %HOMEDRIVE%%HOMEPATH%\ffmpeg.exe -i "%%~nxF" -ac 1 -vol 1024 "%%~nF fixed%%~xF"
  rem
  rem - Your file processing ends here
  rem -------------------------------------------------
  goto :continue
)
:continue
if defined dragDrop (
  pause
  exit
)