Elisp - 循环在alist上

Question

在Emacs Lisp中循环使用alist并对每一对执行某些操作的最佳方法是什么？我想一个宏不会很困难,我只是想知道这是否是在某个地方构建的.有比下面更优雅的方式吗？

(setq my-list '((a . 1)
                (b . 2)
                (c . 3)))

(loop for key in (mapcar 'car my-list)
      for value in (mapcar 'cdr my-list)
      collect (cons value key))

;; Returns this
((1 . a)
 (2 . b)
 (3 . c))

Answer 1

来自cl-macs.el的循环支持像CL这样的破坏:

(loop for (key . value) in my-list
      collect (cons value key))

Answer 2

目前尚不清楚你究竟想做什么 - 问题非常笼统.有很多方法可以循环使用alist并对其部分或全部条目进行操作.你自己展示一种方式.也看看while,特别是,dolist.这是您使用的示例dolist:

    (let ((res  ()))
     (dolist (x my-list)
       (push (cons (cdr x) (car x)) res))
     (nreverse res))

(可能有一种loop比你的例子更好的使用方法- 例如,不需要构建三个列表(两个mapcars + loop).)

Answer 3

另外一种方法loop是使用mapcar和lambda.我不认为它更优雅,但与Common Lisp相比,它更像是elisp的惯用语:

(mapcar (lambda (element)
      (let ((key (car element))
            (value (cdr element)))
      (cons value key)))
      '((1 . a) (2 . b)))

Answer 4

dash.el提供许多列表操作功能,如地图.那些接受函数作为参数也有照应同行.这允许简洁的功能代码.dash.el函数以破折号开头,因此名称和照应版本以2个破折号开头.因此,ataylor的变体看起来会更好:

(--map (cons (cdr it) (car it)) '((1 . a) (2 . b))) ; ((a . 1) (b . 2))