Gnus:如何一次性保存*所有*附件？

Question

我想立即将所有附件保存到电子邮件中.因此,我将gnus-summary-save-parts-default-mime设置为".*/.*".但是,当使用"X m"时,我不仅会获得所有附件,还会收到名为"nnimap+my.name@googlemail.com/INBOX.2393.1"的文件(指的是我正在阅读的电子邮件),其中包含我收到的电子邮件的签名.如何排除此"类型"的文件保存在"X m"上？换句话说:如何为gnus-summary-save-parts-default-mime指定正确的正则表达式以防止保存此文件？

Answer 1

这defadvice将通过排除任何没有文件名的部分来完成您目前想要的操作（在本例中，文章本身也是如此）：

(defadvice gnus-summary-save-parts-1 (around gnus-summary-save-parts-exclude-self activate)
  (let ((handle (ad-get-arg 2)))
    (unless (and (not (stringp (car handle)))
                 (not (mm-handle-filename handle)))
      ad-do-it)))

我使用的是 Gnus v5.13；如果您也使用相同或相似的版本，请告诉我此修改版本是否适合gnus-summary-save-parts-1您；您需要设置gnus-summary-save-parts-exclude-article为t. 如果它对你有用，我将向 Gnus 项目提交一个补丁。

请注意，要么使用上面的代码defadvice ，要么使用下面的代码，但不要同时使用两者。defadvice 是一个简单的快速修复方法，您可以暂时使用。下面的代码我将作为 Gnus 项目的补丁提交，我在这里仅包含此代码供您测试，看看它是否适用于您的系统（如果您也使用 Gnus v5.13）。如果他们接受这个补丁并将其作为未来版本的一部分，那么您将不需要defadvice上述内容；相反，您只能自定义gnus-summary-save-parts-exclude-article变量。

(require 'gnus)
(require 'gnus-sum)

(defcustom gnus-summary-save-parts-exclude-article nil
  "If non-nil don't save article along with attachments."
  :group 'gnus-article-mime
  :type 'boolean)

(defun gnus-summary-save-parts-1 (type dir handle reverse)
  (if (stringp (car handle))
      (mapcar (lambda (h) (gnus-summary-save-parts-1 type dir h reverse))
          (cdr handle))
    (when (if reverse
          (not (string-match type (mm-handle-media-type handle)))
        (string-match type (mm-handle-media-type handle)))
      (let* ((name (or
                    (mm-handle-filename handle)
                    (unless gnus-summary-save-parts-exclude-article
                      (format "%s.%d.%d" gnus-newsgroup-name
                              (cdr gnus-article-current)
                              gnus-summary-save-parts-counter))))
             (file (when name
                     (expand-file-name
                      (gnus-map-function
                       mm-file-name-rewrite-functions
                       (file-name-nondirectory
                        name))
                      dir))))
        (when file
          (incf gnus-summary-save-parts-counter)
          (unless (file-exists-p file)
            (mm-save-part-to-file handle file)))))))