如何编写一个以可变函数作为参数的Haskell函数

Question

我正在尝试创建一个函数,它将一个可变函数作为参数,即

func :: (a -> ... -> a) -> a

我怎么能做到这一点？

我已经阅读了关于多变量函数的信息,我确信Oleg已经做到了,但是我试图将这个模式应用于具有可变函数作为参数的函数.特别是Olegs方法似乎只适用于格拉斯哥扩展,我希望解决方案在纯Haskell 98中工作(就像Text.Printf一样).

我问的原因是我正在尝试构建一个函数,该函数将布尔函数作为参数并检查它是否是重言式,即

isTautology :: (Bool -> ... -> Bool) -> Bool

所以可以输入:

isTautology (\x -> x && not x)
isTautology (\x y -> x && y || not y)

我的问题是,我一直在阅读的技巧是使返回类型成为一个类型变量(这样它可以是结果或另一个函数),但我的返回类型是固定的(Bool).

Answer 1

诀窍是创建一个类型类,您将为其定义函数的实例,以及返回类型的实例.这是一个Bool根本不是问题的事实.

我们正在尝试编写一个采用可变参数并返回a的函数Bool,因此我们将使用这样的函数定义一个类型类.

class Stmt a where
    tautology :: a -> Bool

接下来,我们为可变参数函数的返回类型定义一个实例.在这种情况下,那是Bool.

-- A Bool is a tautology if it's True.
instance Stmt Bool where
    tautology = id

关键部分是接受Bool参数的函数的下一个实例,其返回类型是我们类中的某种类型.这样,如果函数接受多个参数,则该实例将被多次应用.

-- A function is a tautology if it always returns a tautology.
instance Stmt b => Stmt (Bool -> b) where
    tautology f = tautology (f True) && tautology (f False)

以这种方式编写它需要FlexibleInstances因为Bool在第二个实例中头部.为了对纯Haskell 98做同样的事情,我们需要使用适当约束的类型变量.例如,我们可以使用Bounded和Enum(两者都有实例Bool),或者您可以创建自己的类来构建适当的输入.

instance (Enum a, Bounded a, Stmt b) => Stmt (a -> b) where
    tautology f = all (tautology . f) [minBound .. maxBound]

我们已经完成了.我们来试试吧:

> tautology $ \x y -> (not x && not y) == not (x && y)
False
> tautology $ \x y -> (not x && not y) == not (x || y)
True