空白xmlns =""导入的属性

Question

我正在尝试对XML文档进行转换.我的XML转换可以导致两种不同类型的基本元素,具体取决于某个元素的值:

<xsl:template match="/">
  <xsl:choose>
    <xsl:when test="/databean/data[@id='pkhfeed']/value/text()='200'">
      <xsl:call-template name="StructureA">
        <xsl:with-param name="structure" select="//databean" />
      </xsl:call-template>
    </xsl:when>
    <xsl:otherwise>
      <xsl:call-template name="StructureB">
        <xsl:with-param name="structure" select="//databean" />
      </xsl:call-template>
    </xsl:otherwise>
  </xsl:choose>
</xsl:template>

然后使用自己的名称空间和schemaLocations创建StructureA或StructureB:

<StructureA xmlns="http://...">

StructureA&B共享一些共同元素,因此这些元素在一个名为"xmlcommon.xslt"的单独文件中定义,两个结构都包含来自的模板.此xmlcommon文件没有定义默认命名空间,因为我希望它可以从StructureA或StructureB中定义的命名空间中使用.但是当我运行我的转换时,从公共文件中引入的任何模板都会产生空白的xmlns属性:

<StructureA xmlns="http://...">
  <SharedElement xmlns="">Something</SharedElement>
</StructureA>

验证时,然后使用空白名称空间而不是正确的父名称空间. 有谁知道如何阻止我的公共文件中的模板添加那些空白的xmlns属性？

这是公共文件的片段:

<xsl:stylesheet version="1.0" xmlns:fn="http://www.w3.org/2005/02/xpath-functions" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

  <xsl:template name="ControlledListStructure">
    <xsl:param name="xmlElem" />
    <xsl:param name="structure" />

    <xsl:element name="{$xmlElem}">
      <!-- Blah blah blah -->
    </xsl:element>
  </xsl:template>
</xsl:stylesheet>

Answer 1

要实现的关键是你的样式表规定了你添加到结果树的每个元素的名称.元素的名称有两部分:本地名称和名称空间URI.在上面的代码中,您提供了本地名称(值$xmlElem),但是您没有指定名称空间URI,这意味着它将默认为空字符串.(实际上,它采用了该样式表模块的默认命名空间;因为没有,所以它是空字符串.)换句话说,该元素不在命名空间中.在序列化文档时,XSLT处理器必须包含xmlns=""取消声明,以便取消声明顶部显示的默认命名空间.否则,该元素将采用该命名空间,这不是您的样式表所指示的.解决这个问题的最少侵入性的方法是添加另一个参数(例如$namespaceURI),就像你一样$xmlElem.然后你会写:

<xsl:element name="{$xmlElem}" namespace="{$namespaceURI}">

现在,结果元素将采用您告诉它采用的任何命名空间(这将具有删除那些默认命名空间取消声明的效果).

这应该回答你的问题.我提供以下免费奖励材料.;-)

您应该text()在值比较中删除节点测试.您很少需要直接比较文本节点的值.相反,您可以只比较元素本身的字符串值(它被定义为其所有后代文本节点的字符串值的串联).这看起来像这样:

<xsl:when test="/databean/data[@id='pkhfeed']/value = '200'">

这样做的好处是,如果有一个隐藏在其中的注释,您的代码将不会中断:

<value>2<!--test-->00</value>

在这种情况下,有两个文本节点("2"和"00").您的原始测试将失败,因为它会检查它们中的任何一个是否等于"200".在这种情况下不太可能发生,但在任何情况下测试元素的字符串值(与其文本节点子元素相反)是一个很好的做法,这是你的意图.

最后,我鼓励您了解模板规则和XPath上下文.我倾向于避免<xsl:choose>,<xsl:call-template>以及<xsl:with-param>只要有可能.首先,模板规则可以帮助您避免许多丑陋,冗长的XSLT部分.

<xsl:template match="/databean[data[@id='pkhfeed']/value = '200']" priority="1">
  <StructureA xmlns="http://...">
    ...
  </StructureA>
</xsl:template>

<xsl:template match="/databean">
  <StructureB xmlns="http://...">
    ...
  </StructureB>
</xsl:template>

即使您继续使用<xsl:call-template>,也不必传递该$structure参数,因为当前节点在被调用模板中将保持不变.您可以从您的模板或模板中轻松访问//databean(或者/databean,我怀疑是您的意思),因为当前节点仍然是"/"(文档节点).StructureAStructureB

如果您有兴趣了解有关XSLT核心处理模型及其最强大功能(模板规则)的更多信息,那么我建议您查看"XSLT如何工作",这是我的XSLT 1.0 Pocket Reference中的免费样本章节.

我希望这对你有所帮助,即使它比你讨价还价还要多!